Hican

'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' AUTHOR  : http://www.hican.net - @hicannet
' DATE    : 17-01-2012
' COMMENT : This script installs the Oracle / Siebel
'           webclient and it kills the predeploy.htm
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Set objShell      = CreateObject("Wscript.Shell")
Set objFSO        = CreateObject("Scripting.FileSystemObject")
Set objLogFileFSO = CreateObject("Scripting.FileSystemObject")
Set wshSystemEnv  = objShell.Environment("SYSTEM")
Set objProcessEnv = objShell.Environment("PROCESS")
Set objReg        = GetObject("winmgmts:{impersonationLevel=" _ 
                    & "impersonate}!\\.\root\default:StdRegProv")
Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
 
CurrentDir        = Left(Wscript.ScriptFullname, InstrRev(Wscript.ScriptFullname, "\"))
strLogLocation    = objShell.ExpandEnvironmentStrings("%WinDir%") _ 
                    & "\system32\logfiles"
 
Const SilentParam        = " /qb!"
Const AllUsers           = " ALLUSERS=1"
Const HKEY_LOCAL_MACHINE = &H80000002
Const ForWriting         = 2
Const ForReading         = 1
Const ForAppending       = 8
Const OverWriteFiles     = True
 
CreateFolderStructure(strLogLocation)
strLogLocation           = strLogLocation & "\"
strSiebelInstallLogFile  = strLogLocation & "Siebel_Web_Client_" _ 
                           & Replace(FormatDateTime(Now(), 2),"/","-") & ".log"
 
If  objLogFileFSO.FileExists(strSiebelInstallLogFile) Then
  Set objLogFile = objLogFileFSO.OpenTextFile(strSiebelInstallLogFile, ForWriting)
Else
  Set objLogFile = objLogFileFSO.CreateTextFile(strSiebelInstallLogFile)
End If
 
strremoteServerMobileClient = "<IP_ADDRESS>"
strORACLE_HOME              = "C:\Siebel\8.1\Client_1"
strORACLE_HOME_NAME         = "Siebel8_home1"
strINVENTORY_LOCATION       = strLogLocation & "Siebel_Web_Client_" _ 
                              & Replace(FormatDateTime(Now(), 2),"/","-")
strArchitecture             = ""
strOperatingSystemCaption   = ""
strOperatingSystemVersion   = ""
 
' ------------------------------------------------------------------------------
' Find the processor architecture
' ------------------------------------------------------------------------------
Set colItems = objWMIService.ExecQuery("Select Architecture from Win32_Processor")
For Each objItem In colItems
  If objItem.Architecture = 0 Then strArchitecture = "x86"
  If objItem.Architecture = 9 Then strArchitecture = "x64"
Next
 
' ------------------------------------------------------------------------------
' Step 1: Checks the prerequisites. Windows Vista (and above) is not supported 
' by Oracle.
' ------------------------------------------------------------------------------
PrerequisiteChecks
 
' Avoid the File Open dialog.
objProcessEnv("SEE_MASK_NOZONECHECKS") = 1
 
' ------------------------------------------------------------------------------
' Step 2: Install ActivePerl
' ------------------------------------------------------------------------------
InstallActivePerl
 
' ------------------------------------------------------------------------------
' Step 3: Force shutdown of internet explorer
' ------------------------------------------------------------------------------
WriteToLog "Action: -> Executing: Kill both IE and Java processes (if running)"
fnKillProcess("iexplore.exe")
fnKillProcess("java.exe")
fnKillProcess("javaw.exe")
fnKillProcess("mshta.exe")
 
' ------------------------------------------------------------------------------
' Step 4: Install the Oracle Web Client 8.1 Silent
' ------------------------------------------------------------------------------
InstallOracleWebClient81Silent
 
' ------------------------------------------------------------------------------
' Step 5: Install the Oracle Web Client 8.1.1.3 Silent
' ------------------------------------------------------------------------------
InstallOracleWebClient8113Silent
 
' ------------------------------------------------------------------------------
' Step 6: Set the ORACLE_HOME system environment variable
' Step 7: Modify the PATH system and process environment variable.
' ------------------------------------------------------------------------------
ModifyEnvironmentVariables
 
' ------------------------------------------------------------------------------
' Step 8: Copy the Oracle Patches to a folder under ORACLE_HOME
' Step 9: Run 'OPatch' to upgrade the installation
' ------------------------------------------------------------------------------
InstallOraclePatches
 
' ------------------------------------------------------------------------------
' Step 10: Modify the start menu
' ------------------------------------------------------------------------------
ModifyStartMenu
 
' ------------------------------------------------------------------------------
' Step 11: Predeploy all the ocx, dll files for Internet Explorer. Also process 
' the .inf files.
' ------------------------------------------------------------------------------
PredeployOracleCABFiles
PredeployOracleINFFiles
 
WriteToLog "-------------------------------------------------------------------"
WriteToLog "Installation has completed."
WriteToLog "-------------------------------------------------------------------"
 
objProcessEnv.Remove("SEE_MASK_NOZONECHECKS")
fnKillProcess("mshta.exe")
 
Sub PrerequisiteChecks
' ------------------------------------------------------------------------------
' Subroutine: PrerequisiteChecks
' Checks the OS version. If Windows 7 (or higher) then quit.
' ------------------------------------------------------------------------------
 
' ------------------------------------------------------------------------------
' Step 1: find the OS version
' ------------------------------------------------------------------------------
Set colItems = objWMIService.ExecQuery("Select Version from Win32_OperatingSystem")
 
For Each objItem In colItems
  strOperatingSystemVersion = objItem.Version
Next
 
' ------------------------------------------------------------------------------
' Step 2: find the OS Caption
' ------------------------------------------------------------------------------
Set colItems = objWMIService.ExecQuery("Select Caption from Win32_OperatingSystem")
 
For Each objItem In colItems
  strOperatingSystemCaption = objItem.caption
Next
 
strMessage = "Found OS '" & strOperatingSystemCaption & _ 
             "' (" & strOperatingSystemVersion & ") (" & strArchitecture & ")"
WriteToLog strMessage
 
If Left(strOperatingSystemVersion,1) > 5 Then
  strMessage = "The OS '" & strOperatingSystemCaption & _ 
               "' is not supported by Oracle. The installation will be aborted."
  WriteToLog strMessage
  MsgBox strMessage,16,"Oracle Web Client"
  WScript.Quit
End If
End Sub
 
Sub ShowHTA(strHTAFile)
' ------------------------------------------------------------------------------
' Subroutine: ShowHTA(strHTAFile)
' Shows a HTA file on the screen.
' trHTAFile = "c:\folder\folder1\folder2\filename.hta"
' ------------------------------------------------------------------------------
fnKillProcess("mshta.exe")
strCommand = Chr(34) & strHTAFile & Chr(34)
WriteToLog "Action: -> Executing: " & Chr(34) & strHTAFile & Chr(34)
objshell.run Chr(34) & strHTAFile & Chr(34),0,False
End Sub
 
Sub CreateFolderStructure(strFolderNameToBeCreated)
' ------------------------------------------------------------------------------
' Subroutine: CreateFolderStructure(strFolderNameToBeCreated)
' Creates the folderstructure as mentioned. Do not add a trailing '\'
' strFolderNameToBeCreated = "c:\folder\folder1\folder2"
' ------------------------------------------------------------------------------
Dim arrFolders : arrFolders = split (strFolderNameToBeCreated,"\")
Dim strFolder  : strFolder  = ""
Dim objFolder
 
For Each objFolder In arrFolders
  strFolder = strFolder & objFolder
  If NOT objFSO.FolderExists(strFolder) Then
    objFSO.CreateFolder(strFolder)
  End If
  strFolder = strFolder & "\"
Next
End Sub
 
Function fnKillProcess(strProcessName)
' ------------------------------------------------------------------------------
' Function: fnKillProcess(strProcessName)
' Terminates the given processname.
' ------------------------------------------------------------------------------
Set fn_objWMIService = GetObject("winmgmts:{impersonationLevel=" _
                       & "impersonate}!\\.\root\cimv2")
Set colProcess = fn_objWMIService.ExecQuery ("Select * From Win32_Process")
For Each objProcess In colProcess
  If LCase(objProcess.Name) = LCase(strProcessName) Then
     objProcess.Terminate()
  End If
Next
End Function
 
Function fn_WaitForProcessToStart(strProcessName)
' ------------------------------------------------------------------------------
' Function: fn_WaitForProcessToStart(strProcessName)
' This function waits for a process to start. If the given processname is 
' running, then the function is quit.
' strProcessName = the process to be checked.
' ------------------------------------------------------------------------------
blnProcessFound = False
Set fn_objSWbemServices = GetObject("winmgmts:\\.\root\cimv2")
Do 
  WScript.Sleep 2500
  Set colSWbemObjectSet = fn_objSWbemServices.InstancesOf("Win32_Process")
  For Each objSWbemObject In colSWbemObjectSet
    If (LCase(objSWbemObject.Name) = LCase(strProcessName)) Then
      blnProcessFound = True
    End If
  Next
Loop Until blnProcessFound
End Function
 
Function fn_WaitForARunningProcess(strProcessName)
' ------------------------------------------------------------------------------
' Function: fn_WaitForARunningProcess(strProcessName)
' This function waits for a process to stop. When the processname is not 
' running anymore, this function will quit.
' strProcessName = the process to be checked.
' ------------------------------------------------------------------------------
Set fn_objSWbemServices = GetObject("winmgmts:\\.\root\cimv2")
Set colSWbemObjectSet = fn_objSWbemServices.InstancesOf("Win32_Process")
For Each objSWbemObject In colSWbemObjectSet
  If (LCase(objSWbemObject.Name) = LCase(strProcessName)) Then
    Wscript.Sleep(2500)
    fn_WaitForARunningProcess(strProcessName)
  End If
Next
End Function
 
Function WriteToLog(sLogMessage)
' ------------------------------------------------------------------------------
' Function: WriteToLog(sLogMessage)
' This function writes an entry in a log file.
' sLogMessage = The message to be written in the log file.
' ------------------------------------------------------------------------------
  objLogFile.WriteLine("Time: " & now & "  " & sLogMessage)
End Function
 
Function fnWriterunningProcessesToLogFile()
' ------------------------------------------------------------------------------
' Function: fnWriterunningProcessesToLogFile
' Writes all the running processes to a log file.
' ------------------------------------------------------------------------------
Set fn_objWMIService = GetObject("winmgmts:{impersonationLevel=" _
                       & "impersonate}!\\.\root\cimv2")
 
Set colProcess = fn_objWMIService.ExecQuery ("Select * From Win32_Process")
For Each objProcess In colProcess
  WriteToLog(" --> Running process: " & objProcess.Name)
Next
End Function
 
' ------------------------------------------------------------------------------
' The following subroutines are used to install the components.
' ------------------------------------------------------------------------------
Sub InstallActivePerl
' ------------------------------------------------------------------------------
' Sub InstallActivePerl
' Only installs ActivePerl if not already installed.
' Use WMI to find the processor architecture.
' The variable %PROCESSOR_ARCHITECTURE% always returns x86 (under sytem 
' context). That is why WMI is used.
' ------------------------------------------------------------------------------
If strArchitecture = "x86" Then
  strMSIFileName = CurrentDir & "1-ActivePerl" & Chr(92) _ 
                   & "ActivePerl-5.14.2.1402-MSWin32-x86-295342.msi"
  strLogfile = "ActivePerl-5.14.2.1402-MSWin32-x86-295342.log"
  strExecuteCommand = "msiexec.exe /i " & Chr(34) & strMSIFileName _ 
                      & Chr(34) & SilentParam & Allusers & " /l*v " _ 
                      & Chr(34) & strLogLocation & strLogfile & Chr(34)
  WriteToLog "Action: -> Executing: " & strExecuteCommand
  objShell.Run strExecuteCommand,0,True
End If
 
If strArchitecture = "x64" Then
  strMSIFileName = CurrentDir & "1-ActivePerl" & Chr(92) _ 
                   & "ActivePerl-5.14.2.1402-MSWin32-x64-295342.msi"
  strLogfile = "ActivePerl-5.14.2.1402-MSWin32-x64-295342.log"
  strExecuteCommand = "msiexec.exe /i " & Chr(34) & strMSIFileName & Chr(34) _ 
                      & SilentParam & Allusers & " /l*v " & Chr(34) _ 
                      & strLogLocation & strLogfile & Chr(34)
  WriteToLog "Action: -> Executing: " & strExecuteCommand
  objShell.Run strExecuteCommand,0,True
End If
End Sub
 
Sub InstallOracleWebClient81Silent
' ------------------------------------------------------------------------------
' Sub InstallOracleWebClient81Silent
' Installs the Oracle Web Client 8.1
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_1_Installing_8.1.hta")
 
strFROM_LOCATION  = CurrentDir & "2-8.1\Siebel_Web_Client\Disk1\stage\products.xml"
strExecuteCommand = Chr(34) & CurrentDir _
                    & "2-8.1\Siebel_Web_Client\Disk1\install\oui.exe" & Chr(34) _ 
                    & " -ignoreSysPrereqs -noconsole -silent -nowait -force" _ 
                    & " -responseFile " & Chr(34) & CurrentDir _ 
                    & "6-RSPFiles\Siebel81.rsp" & Chr(34) _ 
                    & " FROM_LOCATION=" & Chr(34) & strFROM_LOCATION & Chr(34) _ 
                    & " remoteServerMobileClient=" & Chr(34) _ 
                    & strremoteServerMobileClient & Chr(34) & " ORACLE_HOME=" _ 
                    & Chr(34) & strORACLE_HOME & Chr(34) & " ORACLE_HOME_NAME=" _ 
                    & Chr(34) & strORACLE_HOME_NAME & Chr(34) _ 
                    & " INVENTORY_LOCATION=" & Chr(34) & strINVENTORY_LOCATION _ 
                    & Chr(34)
WriteToLog "Action: -> Executing: " & strExecuteCommand
blnResult = objShell.Run (strExecuteCommand)
 
WriteToLog "Action: -> Now wait for Internet Explorer screen to come up"
fn_WaitForProcessToStart("iexplore.exe")
WriteToLog "Action: -> Executing: Kill Internet Explorer process"
fnKillProcess ("iexplore.exe")
 
WriteToLog "Action: -> Now wait for Java to finish."
' If run without the -noconsole parameter, then wait for java.exe
fn_WaitForARunningProcess("javaw.exe")
End Sub
 
Sub InstallOracleWebClient8113Silent
' ------------------------------------------------------------------------------
' Sub InstallOracleWebClient8113Silent
' Installs the Oracle Web Client 8.1.1.3
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_2_Installing_8.1.1.3.hta")
 
strFROM_LOCATION  = CurrentDir _
                    & "3-8.1.1.3\Client\Siebel_Web_Client\Disk1\stage\products.xml"
strExecuteCommand = Chr(34) & CurrentDir _ 
                    & "3-8.1.1.3\Client\Siebel_Web_Client\Disk1\install\oui.exe" _ 
                    & Chr(34) & " -ignoreSysPrereqs -noconsole -silent -nowait" _ 
                    & " -force -responseFile " & Chr(34) & CurrentDir _ 
                    & "6-RSPFiles\Siebel8113.rsp" & Chr(34) _ 
                    & " FROM_LOCATION=" & Chr(34) & strFROM_LOCATION & Chr(34) _ 
                    & " ORACLE_HOME=" & Chr(34) & strORACLE_HOME & Chr(34) _ 
                    & " ORACLE_HOME_NAME=" & Chr(34) & strORACLE_HOME_NAME _ 
                    & Chr(34) & " INVENTORY_LOCATION=" & Chr(34) _ 
                    & strINVENTORY_LOCATION & Chr(34)
WriteToLog "Action: -> Executing: " & strExecuteCommand
blnResult = objShell.Run (strExecuteCommand)
 
WriteToLog "Action: -> Wait for Oracle Universal Installer and Java to finish."
fn_WaitForARunningProcess("oui.exe")
WScript.Sleep 10000
'If run without the -noconsole parameter, then wait for java.exe
fn_WaitForARunningProcess("javaw.exe")
End Sub
 
Sub ModifyEnvironmentVariables
' ------------------------------------------------------------------------------
' Sub ModifyEnvironmentVariables
' Modifies the System Environment variables. 
' ------------------------------------------------------------------------------
wshSystemEnv("ORACLE_HOME") = strORACLE_HOME
WriteToLog "The system environment value 'ORACLE_HOME' has been set to " _ 
           & strORACLE_HOME
 
strPATH = wshSystemEnv("PATH")
WriteToLog "The system environment variable PATH has as value: " & strPATH
If InStr(strPATH,"perl") = 0 Then
  wshSystemEnv("PATH")="C:\Perl\bin;" & strPATH
  WriteToLog "The system environment variable PATH has been modified. The " _ 
	           & "new value is " & wshSystemEnv("PATH")
Else
  WriteToLog "The system environment variable PATH has not been modified."
End If
End Sub
 
Sub InstallOraclePatches
' ------------------------------------------------------------------------------
' Sub InstallOraclePatches
' Copies the files to ORACLE_HOME. Then installs 2 oracle Patches. 
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_3_Copy_files.hta")
objFSO.CopyFolder CurrentDir & "4-QF0312" , strORACLE_HOME & "\",OverWriteFiles
objFSO.CopyFolder CurrentDir & "5-QF1302" , strORACLE_HOME & "\",OverWriteFiles
objFSO.CopyFile CurrentDir & "6-RSPFiles\ocm.rsp" , strORACLE_HOME _ 
                           & "\",OverWriteFiles
ShowHTA(CurrentDir & "step_4_Installing_Patch_QF0312.hta")
 
strCommand = "c:\Perl\bin\perl.exe " & strORACLE_HOME _
             & "\4-QF0312\Siebel_Web_Client\OPatch\opatch.pl apply " _
             & strORACLE_HOME & "\4-QF0312\Siebel_Web_Client -silent -force " _
             & "-ocmrf " & strORACLE_HOME & "\ocm.rsp -oh " & strORACLE_HOME
WriteToLog "Action: -> Executing: 'objShell.Run " & strCommand & ",0,True'"
objShell.Run strCommand,0,True
 
ShowHTA(CurrentDir & "step_5_Installing_Patch_QF1302.hta")
 
strCommand = "c:\Perl\bin\perl.exe " & strORACLE_HOME _
             & "\5-QF1302\Siebel_Web_Client\OPatch\opatch.pl apply " _
             & strORACLE_HOME & "\5-QF1302\Siebel_Web_Client -silent -force " _
             & "-ocmrf " & strORACLE_HOME & "\ocm.rsp -oh " & strORACLE_HOME
WriteToLog "Action: -> Executing: 'objShell.Run " & strCommand & ",0,True'"
objShell.Run strCommand,0,True
End Sub
 
Sub ModifyStartMenu
' ------------------------------------------------------------------------------
' Sub ModifyStartMenu
' Removes all unneeded entries from the Start menu and add one shortcut.  
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_6_Modifying_start_menu.hta")
 
strKeyPath   = "SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
strValueName = "Common Programs"
objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strCommonPrograms
 
If objFSO.FolderExists (strCommonPrograms & "\ActivePerl 5.14.2 Build 1402") Then
  WriteToLog "Action: -> Deleting: " & strCommonPrograms _
	           & "\ActivePerl 5.14.2 Build 1402"
  objFSO.DeleteFolder (strCommonPrograms & "\ActivePerl 5.14.2 Build 1402")
End If
 
If objFSO.FolderExists (strCommonPrograms & "\Oracle - " & strORACLE_HOME_NAME) Then
  WriteToLog "Action: -> Deleting: " & strCommonPrograms & "\Oracle - " _ 
	           & strORACLE_HOME_NAME
  objFSO.DeleteFolder (strCommonPrograms & "\Oracle - " & strORACLE_HOME_NAME)
End If
 
If objFSO.FolderExists (strCommonPrograms & Chr(92) & strORACLE_HOME_NAME) Then 
  WriteToLog "Action: -> Deleting: " & strCommonPrograms & "\" & strORACLE_HOME_NAME
  objFSO.DeleteFolder (strCommonPrograms & "\" & strORACLE_HOME_NAME)
End If 
 
Set objLink              = objShell.CreateShortcut(strCommonPrograms _ 
                           & "\Siebel Field Service - ENU.lnk")
objLink.Description      = "Siebel Field Service - ENU"
objLink.IconLocation     = strORACLE_HOME & "\bin\siebel.exe,0"
objLink.TargetPath       = strORACLE_HOME & "\bin\siebel.exe" 
objLink.Arguments        = "/c " & strORACLE_HOME & "\bin\enu\sfs.cfg"
objLink.WindowStyle      = 1
objLink.WorkingDirectory = strORACLE_HOME & "\bin"
objLink.Save
 
WriteToLog "Action: -> Created: icon 'Siebel Field Service - ENU' in " _ 
           & strCommonPrograms
End Sub
 
Sub PredeployOracleCABFiles
' ------------------------------------------------------------------------------
' Sub PredeployOracleCABFiles
' Extracts all the cab files to C:\Windows\Downloaded Program Files.  
' Then the files are registered. 
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_7_predeploy.hta")
 
Set strFolderwithCABFiles = objFSO.GetFolder(strORACLE_HOME _ 
                            & "\PUBLIC\enu\21219\APPLETS")
Set arrCABFiles           = strFolderwithCABFiles.Files
strKeyPathDPF             = "SOFTWARE\Microsoft\Windows\CurrentVersion" _ 
                            & "\Internet Settings\ActiveX Cache"
strValueNameDPF           = "0"
objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPathDPF,strValueNameDPF,strValueDPF
WriteToLog "Folder for Downloaded Program Files is: " & strValueDPF
 
For Each objCABFile In arrCABFiles
  If LCase(Right(objCABFile.Name,4)) = ".cab" Then
    strCommand = "expand -f:*.* " & strORACLE_HOME & "\PUBLIC\enu\21219\APPLETS\" _ 
		             & objCABFile.Name & " " & Chr(34) & strValueDPF & Chr(34)
    WriteToLog "Action: - Executing: objShell.Run " & strCommand & ",0,True"
    objShell.Run StrCommand,0,True
  End If
Next
 
Set strFolderwithDPFiles = objFSO.GetFolder(strValueDPF)
Set arrDPFiles           = strFolderwithDPFiles.Files
WriteToLog "Action: -> Registering or deleting the files in " & strValueDPF
 
For Each objDPFile In arrDPFiles
  strDPFile = lcase(objDPFile.Name)
  If (Left(strDPFile,1)="s" AND Right(strDPFile,4)=".dll") OR _ 
     (Left(strDPFile,1)="s" AND Right(strDPFile,4)=".ocx") OR _ 
     (Left(strDPFile,4)="ieop" AND Right(strDPFile,4)=".dll") Then
    strCommand = "regsvr32 /s " & Chr(34) & strValueDPF & "\" & strDPFile & Chr(34)
    valResult  = objShell.Run(strCommand,6,True)
    If valResult = 0 Then
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' succeeded."
    Else
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' failed."
    End If
  End If
  If (Left(strDPFile,1)="s" AND Right(strDPFile,4)=".exe") Then
    strCommand = Chr(34) & strValueDPF & "\" & strDPFile & Chr(34) & " /regserver"
    valResult  = objShell.Run(strCommand,1,True)
    If valResult = 0 Then
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' succeeded."
    Else
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' failed."
    End If
  End If
  If Right(strDPFile,6)=".class" Then
    objFSO.DeleteFile strValueDPF & "\" & strDPFile
    WriteToLog "Action: The file '" & strValueDPF & Chr(92) & strDPFile _ 
               & "' has been deleted."
  End If
Next
End Sub
 
Sub PredeployOracleINFFiles
' ------------------------------------------------------------------------------
' Sub PredeployOracleINFFiles
' Reads all the .inf files in C:\Windows\Downloaded Program Files. Finds the 
' dll file in the inf file
' and then adds the registration in the registry.
' ------------------------------------------------------------------------------
strKeyPathDPF             = "SOFTWARE\Microsoft\Windows\CurrentVersion" _ 
                            & "\Internet Settings\ActiveX Cache"
strKeyPathModuleUsage     = "SOFTWARE\Microsoft\Windows\CurrentVersion\ModuleUsage\"
strValueNameDPF           = "0"
objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPathDPF,strValueNameDPF,strValueDPF
WriteToLog "Folder for Downloaded Program Files is: " & strValueDPF
 
Set strFolderwithINFFiles = objFSO.GetFolder(strValueDPF)
Set arrINFFiles           = strFolderwithINFFiles.Files
WriteToLog "Action: -> Processing the INF files in " & strValueDPF
 
For Each objINFFile In arrINFFiles
  strINFFile = LCase(objINFFile.Name)
  If Right(strINFFile,4) = ".inf" Then
    strINFFile = strValueDPF & "\" & strINFFile
    WriteToLog "Action: -> Processing INF File: " & strINFFile
    Set objINFFileToRead = objFSO.OpenTextFile(strINFFile, ForReading, False)
    Do While NOT objINFFileToRead.AtEndOfStream
      strLine = Trim(objINFFileToRead.ReadLine)
      strLine = lcase(strLine)
      If Left(strLine,1) = "[" AND Right(strLine,5)=".dll]" Then
        strDLLFileName      = strLine
        ' Remove first '['
        strDLLFileName      = Right(strDLLFileName,Len(strDLLFileName)-1)
        ' Remove last ']'
        strDLLFileName      = Left (strDLLFileName,Len(strDLLFileName)-1)
        WriteToLog "Action: -> Found dll file " & strDLLFileName & " in " _ 
                   & strINFFile & "."
        strDLLFileName = strValueDPF & Chr(92) & strDLLFileName
      End If
      If Left(strLine,5) = "clsid" Then
        arrCLSID = Split(strLine,"=")
        strCLSID = arrCLSID(1)
        WriteToLog "Action: -> Found CLSID " & strCLSID  & " in " & strINFFile & "."
      End If
      strDLLFileName = replace(strDLLFileName, "\","/")
      objReg.CreateKey HKEY_LOCAL_MACHINE,strKeyPathModuleUsage & strDLLFileName
      WriteToLog "Action: -> Created registry key: HKEY_LOCAL_MACHINE\" _ 
                 & strKeyPathModuleUsage & strDLLFileName
      objReg.SetStringValue HKEY_LOCAL_MACHINE,strKeyPathModuleUsage _ 
      & strDLLFileName , ".Owner" , strCLSID
      WriteToLog "Action: -> Created hive '.Owner' with value " & strCLSID _ 
                 & " in HKEY_LOCAL_MACHINE\" & strKeyPathModuleUsage & strDLLFileName
      objReg.SetStringValue HKEY_LOCAL_MACHINE,strKeyPathModuleUsage _ 
      & strDLLFileName , strCLSID , ""
      WriteToLog "Action: -> Created hive '" & strCLSID _ 
                 & "' with an empty value in HKEY_LOCAL_MACHINE\" _ 
                 & strKeyPathModuleUsage & strDLLFileName
    Loop
  End If
Next
End Sub