Hican.net

PowerShell: Rename Photos To Parent Folder Name

hicannet — Thu, 15 Mar 2012 13:35:52 +0000

A colleague of mine asked me if I could make a PowerShell script which would rename all of his jpg photos on his NAS. All photos need to be renamed to the (parent) folder they are in.

I decided to write it in a function with multiple for loops (for readability) and to put in a jpg filter. If you want different files to be renamed, just change that filter (or extend it).

The script can be used by putting it in the root of the folder where all the different photo folders are present and run it.
For example if you have a folder called HolidayPhotos and in that folder multiple folders like Ibiza_2010, Florida_2012, etc. just put the script in the HolidayPhotos folder. Now run the script and all jpg files will be renamed to Ibiza_2010_1, Ibiza_2010_2, etc. and Flordia_2012_1, Florida_2012_2, etc.

rename_photos.ps1

#######################################################
# AUTHOR  : http://www.hican.net - @hicannet
# DATE    : 12-03-2012
# COMMENT : This script renames all .jpg files to the
#           name of the .jpg parent folder recursively,
#           extended with an increasing number.
#           Put the script in the root of the folders'
#           parent folder.
#######################################################
$path = Split-Path -parent $MyInvocation.MyCommand.Definition
 
Function renamePhotos
{
  # Loop through all directories
  $dirs = dir $path -Recurse | Where { $_.psIsContainer -eq $true }
  Foreach ($dir In $dirs)
  {
    $i = 1
    $newdir = $dir.name + "_"
    $images = Get-ChildItem -Path $dir.fullname -Filter *.jpg -Recurse
    Foreach ($image In $images)
    {
      $split    = $image.name.split(".jpg")
      $replace  = $split[0] -Replace $split[0],($newdir + $i + ".jpg")
 
      $image_string = $image.fullname.ToString().Trim()
      Rename-Item "$image_string" "$replace"
      $i++
    }
  }
}
# RUN SCRIPT
renamePhotos
"SCRIPT FINISHED"

VBScript: Auto Create SCCM Collections

hicannet — Tue, 06 Mar 2012 10:16:30 +0000

During a project it was required to do extensive and recurring cleanups of applications within that specific company. The cleanup was done in Active Directory by checking who wasn’t supposed to be a member of the application groups, but also through SCCM.

For the SCCM cleanup 3 different Collections were used: Uninstall Query, Install Overview and a User Overview. These collections were created by hand and took quite some time, because a lot applications had to be cleaned from time to time (mainly licensed applications).

To easen things we decided to create a VBScript to auto create the uninstall collections, based on an input.csv.

Note #1: Check an example of the input.csv at the bottom of the page.
Note #2: This script also contains a logging / output function which outputs the actions to an output.csv.

create_uninstall_collections.vbs

'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' AUTHOR  : http://www.hican.net - @hicannet
' DATE    : 06-03-2012
' COMMENT : This script auto creates (removal) 
'           Collections based on an input csv file.
'           Including Logging.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Option Explicit
 
Const ForWriting = 2
Const ForReading = 1
Const ForAppending = 8
 
Dim objWshShell, objFso, objFile, objEnv, objLogFileFSO, objLogFile
Dim swbemLocator, swbemconnection, providerLoc, Location
Dim sConnect, sCurPath, sInputFile, sOutputFile, sNextLine, sSplit
Dim sParent, sAppName, sAll, sC2R, sInstalls, sUsers, sUsrName, sComment
Dim sColCheck, Collection, objCollection, newCollection, collectionPath
Dim sCollectionID, objContainerNode, Container, ParentFolderID, sResourceID
Dim newCollectionRelation, Token, objNewCollection, sColInput, sLimitID
Dim newQueryRule, newCollectionRule, sQueryC2R, sQueryInstalls, sQueryUsers
Dim sGroupName, sProductID
 
sConnect        = ""
sCurPath        = left(WScript.ScriptFullName,(Len(WScript.ScriptFullName))-(len(WScript.ScriptName)))
sInputFile      = sCurPath + Chr(92) + "input.csv"
sOutputFile     = sCurPath + Chr(92) + "output.csv"
 
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objFso      = CreateObject("Scripting.FileSystemObject")
Set objFile     = objFso.OpenTextFile(sInputFile, ForReading)
Set objEnv      = objWshShell.Environment("process")
 
'Try to make a connection with the SCCM server.
ConnectToSCCM
 
OpenLogFile()
WriteToLog "-------------------------------------------------------------------" & VbCrLf
WriteToLog "START LOG  (" + FormatDateTime(Now(), vbGeneralDate)
 
Do Until objFile.AtEndOfStream
  sNextLine  = objFile.Readline
  sSplit     = Split(sNextLine, ";")
  sParent    = sSplit(0)
  sAppName   = sSplit(1)
  sProductID = sSplit(2)
  sGroupName = sSplit(3)
 
  sAll       = "All_" + sAppName
  sC2R       = "C2R_" + sAppName
  sInstalls  = "Installs_" + sAppName
  sUsers     = "Users_" + sAppName
 
  sQueryC2R      = "select SMS_R_SYSTEM.ResourceID,SMS_R_SYSTEM.ResourceType,SMS_R_SYSTEM.Name,SMS_R_SYSTEM.SMSUniqueIdentifier,SMS_R_SYSTEM.ResourceDomainORWorkgroup,SMS_R_SYSTEM.Client from SMS_R_System INNER JOIN SMS_R_User ON SMS_R_System.LastLogonUserName = SMS_R_User.UserName WHERE (SMS_R_System.Name NOT IN (SELECT SMS_R_System.Name FROM SMS_R_User INNER JOIN SMS_R_System ON SMS_R_User.Username = SMS_R_System.LastLogonUserName WHERE (SMS_R_User.UserGroupName = 'Hican.net\\" + sGroupName + "'))) AND (SMS_R_System.Name IN (SELECT SMS_R_System.Name FROM SMS_R_System AS SMS_R_System INNER JOIN SMS_G_System_ADD_REMOVE_PROGRAMS ON SMS_R_System.ResourceID = SMS_G_System_ADD_REMOVE_PROGRAMS.ResourceID WHERE (SMS_G_System_ADD_REMOVE_PROGRAMS.ProdID = '" + sProductID + "')))"
  sQueryInstalls = "select SMS_R_SYSTEM.ResourceID,SMS_R_SYSTEM.ResourceType,SMS_R_SYSTEM.Name,SMS_R_SYSTEM.SMSUniqueIdentifier,SMS_R_SYSTEM.ResourceDomainORWorkgroup,SMS_R_SYSTEM.Client from SMS_R_System inner join SMS_G_System_ADD_REMOVE_PROGRAMS on SMS_G_System_ADD_REMOVE_PROGRAMS.ResourceID = SMS_R_System.ResourceId where SMS_G_System_ADD_REMOVE_PROGRAMS.ProdID = '" + sProductID + "'"
  sQueryUsers    = "select SMS_R_USER.ResourceID,SMS_R_USER.ResourceType,SMS_R_USER.Name,SMS_R_USER.UniqueUserName,SMS_R_USER.WindowsNTDomain from SMS_R_USER WHERE (SMS_R_USER.USERGROUPNAME = 'Hican.net\\" + sGroupName + "')"
 
  sUsrName  = objEnv("USERNAME")
  sComment  = "Created via script by " + sUsrName + " on " + Replace(FormatDateTime(Now(), vbShortDate), "/", "-")
  sColCheck = ""
 
  If (Left(sNextLine, 1) = "*") Then
    WriteToLog "LINE: " & sNextLine & " DISABLED FOR PROCESSING..."
  Else
    CreateCollections(sAll)
    CreateCollections(sC2R)
    CreateCollections(sInstalls)
    CreateCollections(sUsers)
  End If
Loop
 
objFile.Close
 
WriteToLog "-------------------------------------------------------------------" & VbCrLf
CloseLogFile()
Wscript.Echo "Finished creating the Collections!"
Wscript.Quit
 
'''''''''''''''''''''''''''''
'         FUNCTIONS         '
'''''''''''''''''''''''''''''
Function ConnectToSCCM
On Error Resume Next
Set swbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set swbemconnection = swbemLocator.ConnectServer(sConnect, "root\sms")
Set providerLoc = swbemconnection.InstancesOf("SMS_ProviderLocation")
 
For Each Location In providerLoc
  If location.ProviderForLocalSite = True Then
    Set swbemconnection = swbemLocator.ConnectServer(Location.Machine, "root\sms\site_" + Location.SiteCode)
    Exit For
  End If
Next
If Err.Number <> 0 Then
  Wscript.echo "Unable to connect to the SCCM provider. " & _
               "Check the connection and / or the settings in the script!" & _
               "The script will be stopped now."
  WScript.Quit
End If
On Error GoTo 0
End Function
 
Sub OpenLogFile()  	
Set objLogFileFSO = CreateObject("Scripting.FileSystemObject")
If objLogFileFSO.FileExists(sOutputFile) Then
  Set objLogFile = objLogFileFSO.OpenTextFile(sOutputFile, ForAppending)
Else
  Set objLogFile = objLogFileFSO.CreateTextFile(sOutputFile)
End If	
End Sub
 
Sub CloseLogFile()
objLogFile.Close	
Set objLogfileFSO = Nothing
End Sub
 
Function WriteToLog(sLogMessage)
  objLogFile.WriteLine(sLogMessage)
End Function
 
Function ConvertToWMIdate(sDate)
'Attempts to convert the date into a WMI date-time!
Dim sYear, sMonth, sDay, sHour, sMinute
 
sYear = year(sDate)
sMonth = month(sDate)
sDay = day(sDate)
sHour = hour(sDate)
sMinute = minute(sDate)
 
If len(sMonth) = 1 Then
  sMonth = "0" & sMonth
End If
If len(sDay) = 1 Then
  sDay = "0" & sDay
End If
If len(sHour) = 1 Then
  sHour = "0" & sHour
End If
If len(sMinute) = 1 Then
  sMinute = "0" & sMinute
End If
 
ConvertToWMIdate = sYear & sMonth & sDay & sHour & sMinute & "00.000000+***"
End Function
 
 
Function CreateCollections(sColInput)
'Attempts to check if the collection already exists. If it does, 
'the script will skip this creation!
Set Collection = swbemconnection.ExecQuery ("select * from SMS_Collection where Name='" & sParent & "'")
For Each objCollection In Collection
  sColCheck = "This collection exists with the collection ID of: " & objCollection.CollectionID
Next
 
If sColCheck = "" Then
  WScript.Echo "ParentFolder " + sParent + " is not present in Collections - " & _
               "Management Collections - Special Collections - SMS Cleanup " & _ 
               ", please create that folder first. The script will be stopped now."
  WScript.Quit
Else
  'Attempts to create the new collections.
  Set newCollection = swbemconnection.Get("SMS_Collection").SpawnInstance_()
 
  newCollection.Name = sColInput
  newCollection.OwnedByThisSite = True
  newCollection.Comment = sComment
  Set collectionPath = newCollection.Put_
 
  'Attempts to obtain the collection ID of the 
  'newly created collection!
  Set Collection = swbemconnection.ExecQuery ("select * from SMS_Collection where Name='" & sColInput & "'")
  For Each objCollection in Collection
    sCollectionID = objCollection.CollectionID
  Next
 
  If sCollectionID = "" Then
    WScript.Echo "Unable to obtain a collection ID for the newly created collection."
    WScript.Quit
  Else
    'WScript.Echo sCollectionID
  End If
 
  If sColInput = sAll Then
    Set objContainerNode = swbemconnection.ExecQuery("select * from SMS_Collection where Name='" & sParent & "'")
  Else
    Set objContainerNode = swbemconnection.ExecQuery("select * from SMS_Collection where Name='" & sAll & "'")
  End If
 
  'ParentFolderID = ""
  For Each Container In objContainerNode
    If Container.name = sParent Then
      ParentFolderID = Container.CollectionID
    Elseif Container.name = sAll Then
      ParentFolderID = Container.CollectionID
    Else
      'WScript.Echo ParentFolderID
    End If
  Next
 
  'Attempts to move the newly created collection into the 
  'desired parent collection.
  Set newCollectionRelation = swbemconnection.Get("SMS_CollectToSubCollect").SpawnInstance_()
  newCollectionRelation.parentCollectionID = ParentFolderID
  newCollectionRelation.subCollectionID = sCollectionID
  newCollectionRelation.Put_
 
  'Attempts to create and add the query rule group
  'to the collection!
  If sColInput = sC2R OR sColInput = sInstalls OR sColInput = sUsers Then
    Set Collection = swbemconnection.ExecQuery ("select * from SMS_Collection where Name='All Managed Workstations'")
    For Each objCollection in Collection
      sLimitID = objCollection.CollectionID
    Next
 
    Set newQueryRule = swbemconnection.Get("SMS_CollectionRuleQuery").SpawnInstance_()
    If sColInput = sC2R Then
      newQueryRule.QueryExpression     = sQueryC2R
      newQueryRule.LimitToCollectionID = sLimitID
    Elseif sColInput = sInstalls Then
      newQueryRule.QueryExpression     = sQueryInstalls
      newQueryRule.LimitToCollectionID = sLimitID
    Elseif sColInput = sUsers Then
      newQueryRule.QueryExpression     = sQueryUsers
    End If
    newQueryRule.RuleName = sColInput
 
    'Add the new query rule to a variable.
    Set newCollectionRule = newQueryRule
    'Get the collection.
    Set newCollection = swbemconnection.Get(collectionPath.RelPath)
    'Add the rules to the collection.
    newCollection.AddMembershipRule newCollectionRule
    newCollection.RequestRefresh False 
  End If
 
  'Attempts to set the membership update schedule on the 
  'collection (weekly recurrance)!
  Set Token = swbemconnection.Get("SMS_ST_RecurWeekly")
  Token.StartTime = ConvertToWMIdate(Now())
 
  Set objNewCollection = swbemconnection.Get ("SMS_Collection.CollectionID='" & sCollectionID & "'")
  objNewCollection.RefreshSchedule = Array(Token)
  objNewCollection.RefreshType = 2
  objNewCollection.Put_
 
  WriteToLog "CREATED: " & sColInput
End If
End Function

The input.csv has a format like this:
;;;

Example input.csv

'MicrosoftProducts;Microsoft_MapPoint_2007;{C82185E8-C27B-4EF4-2010-2222BC2C2B6D};GG.APP.MICROSOFT_MAPPOINT_2007
'AdobeProducts;Adobe_Reader_X;{C82185E8-C27B-4EF4-2010-2222BC2C2B6D};GG.APP.ADOBE_READER_X

PowerShell: Count AD Users In Active Directory OU’s

hicannet — Tue, 21 Feb 2012 07:38:17 +0000

For a large customer I had to count the amount of users in different kind of OU’s which were member of different kind of country OU’s. This was needed because the under laying OU’s were used as some sort of Profile Groups. Different people with different roles got added to these groups and we wanted to know how many users would get certain (licensed) applications when we would add an application group to these Profile Groups.

Just change the variables in the script for logfile, country and of course the domain to make this work. You could also extend it by adding more variables or change the current ones. If you need help with this, feel free to contact me.

Note #1: This script makes use of the Active Directory Module for PowerShell.
Note #2: I made some extra variables like $usercount and $groupname for the readability and to make the reporting to a logfile easier. This could be written shortened, but I chose for more readability.

count_ad_users_OU_array.ps1

#######################################################
# AUTHOR  : http://www.hican.net - @hicannet
# DATE    : 21-02-2012
# COMMENT : This script retrieves and counts all users
#           from an array of OU's (countries in this
#           specific case) in Active Directory.
Import-Module ActiveDirectory
# Logfile
$log = ""
# OU Array
$country  = "NL","DE","FR","ES","UK"
$country += "AT","RU","PT","SE","US"
# FUNCTIONS
Function getUsers
{
  # Loop through all countries in the $country array
  "-- User Count for sub OU's in each country OU --" | Out-File $log
  Foreach ($cntry In $country)
  {
    "`r`n" + "-- Country - " + $cntry | Out-File $log -append
    $rbacs = Get-ADGroup -Filter * -SearchBase ("OU=Profiles,OU="+$cntry+",OU=Groups,,DC=hican,DC=net")
    Foreach ($rbac In $rbacs)
    {
      If(($rbac | %{$_.Name}) -like "$cntry-Management*" -Or ($rbac | %{$_.Name}) -like "$cntry-Sales*")
      {
        $users   = Get-ADGroupMember $rbac -recursive | Measure-Object
        $usercount = $users | %{$_.Count}
        $groupname = $rbac | %{$_.Name}
        $groupname + " (" + $usercount + ")" | Out-File $log -append
        $usersub   += $usercount
        $usertotal += $usercount
      }
    }
    $cntry + " User Count: " + $usersub | Out-File $log -append
    $usersub = 0
  }
  "`r`n" + "Total User Count: " + $usertotal | Out-File $log -append
  "`r`n" + "--------------------------------------------" + "`r`n" | Out-File $log -append
}
# RUN SCRIPT
getUsers
"SCRIPT FINISHED"

VBScript: Adjust Program Attributes SCCM

hicannet — Mon, 13 Feb 2012 12:29:15 +0000

During our current project we needed to change some program attributes for all programs / applications. The amount of packages was well over 300 and the amount of programs was even more. Therefore I decided a script had to be made.

This script loops through the SMS_Package table / view in SCCM (database) and adjusts all programs based on the input in the script. The script can also be adjusted that it skips certain groups / folders, but that wasn’t needed for this project.

Note: Check the subscript at the bottom of the page for the ‘skip folder’ addition.

adjust_program_attributes.vbs

'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' AUTHOR  : http://www.hican.net - @hicannet
' DATE    : 13-02-2012
' COMMENT : This script adjusts the properties of
'           Application / Package Programs in SCCM.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Option Explicit
 
Dim swbemLocator, swbemconnection, providerLoc, Location
Dim sConnect, PackageFound, ProgramFound, Packages, Package
Dim PackageID, Programs, Program, adjustProgram, programQuery
Dim RUN_ON_SPECIFIED_PLATFORMS, wbemFlagForwardOnly
Dim wbemFlagReturnImmediately, tempSupportedPlatform(3)
Dim tempSupportedPlatformsArray, programPath, checkPlatformValue
Dim allProgramsForPackage
 
sConnect = ""
 
ConnectToSCCM
AdjustPrograms()
 
Wscript.Echo "Finished!"
Wscript.Quit
 
'''''''''''''''''''''''''''''
'         FUNCTIONS         '
'''''''''''''''''''''''''''''
Function ConnectToSCCM
On Error Resume Next
Set swbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set swbemconnection = swbemLocator.ConnectServer(sConnect, "root\sms")
Set providerLoc = swbemconnection.InstancesOf("SMS_ProviderLocation")
 
For Each Location In providerLoc
  If location.ProviderForLocalSite = True Then
    Set swbemconnection = swbemLocator.ConnectServer(Location.Machine, "root\sms\site_" + Location.SiteCode)
    Exit For
  End If
Next
If Err.Number <> 0 Then
  Wscript.echo "Unable to connect to the SCCM provider. " & _
               "Check the connection and / or the settings in the script!" & _
               "The script will be stopped now."
  WScript.Quit
End If
On Error GoTo 0
End Function
 
Function AdjustPrograms()
Set Packages = swbemconnection.ExecQuery("Select * From SMS_Package")
 
For Each Package In Packages
  PackageID = Package.PackageID
 
  programQuery = "SELECT * FROM SMS_Program WHERE PackageID='" & PackageID & "'"
  Set allProgramsForPackage = swbemconnection.ExecQuery(programQuery, , wbemFlagForwardOnly Or wbemFlagReturnImmediately)
 
  For Each program In allProgramsForPackage
 
    'Set the flags according to your environment!
    'program.ProgramFlags = ""
 
    'All x86 Windows XP
    Set tempSupportedPlatform(0) = swbemconnection.Get("SMS_OS_Details").SpawnInstance_
        tempSupportedPlatform(0).MaxVersion = "5.10.9999.9999"
        tempSupportedPlatform(0).MinVersion = "5.10.0000.0"
        tempSupportedPlatform(0).Name       = "Win NT"
        tempSupportedPlatform(0).Platform   = "I386"
 
    'All x86 Windows 7
    Set tempSupportedPlatform(1) = swbemconnection.Get("SMS_OS_Details").SpawnInstance_
        tempSupportedPlatform(1).MaxVersion = "6.10.9999.9999"
        tempSupportedPlatform(1).MinVersion = "6.10.0000.0"
        tempSupportedPlatform(1).Name       = "Win NT"
        tempSupportedPlatform(1).Platform   = "I386"
 
    'All x64 Windows XP Professional
    Set tempSupportedPlatform(2) = swbemconnection.Get("SMS_OS_Details").SpawnInstance_
        tempSupportedPlatform(2).MaxVersion = "5.20.9999.9999"
        tempSupportedPlatform(2).MinVersion = "5.20.3790.0"
        tempSupportedPlatform(2).Name       = "Win NT"
        tempSupportedPlatform(2).Platform   = "x64"
 
    'All x64 Windows 7 Professional
    Set tempSupportedPlatform(3) = swbemconnection.Get("SMS_OS_Details").SpawnInstance_
        tempSupportedPlatform(3).MaxVersion = "6.10.9999.9999"
        tempSupportedPlatform(3).MinVersion = "6.10.0000.0"
        tempSupportedPlatform(3).Name       = "Win NT"
        tempSupportedPlatform(3).Platform   = "x64"
 
    program.SupportedOperatingSystems = tempSupportedPlatform
    program.Put_                    
  Next
Next
End Function

To get this working with the above script, replace AdjustPrograms() with CheckFolder and as you can see, AdjustPrograms() will be called from within this new function.

Addition to above script to skip certain folders in SCCM:

Dim Folders, Folder, objConnectionDB
Dim objCommand, objRecordSet, objOutput
Dim sSplit, n, objQuery, sPackageName
 
Set objRecordSet = CreateObject("ADODB.Recordset")
Set objConnectionDB = CreateObject("ADODB.Connection")
objConnectionDB.Open "Provider=SQLOLEDB;Data Source=;" & "Trusted_Connection=Yes;Initial Catalog=;"
 
Function CheckFolder()
 
objQuery = "SELECT * FROM vPackage " & _
           "INNER JOIN vFolderMembers ON vPackage.PkgID = vFolderMembers.InstanceKey " & _
           "INNER JOIN vSMS_Folders ON vFolderMembers.ContainerNodeID = vSMS_Folders.ContainerNodeID " & _
           "WHERE vSMS_Folders.Name <> 'Server Tooling' " & _
           "AND vSMS_Folders.Name <> 'Decommissioned'"
 
objRecordSet.Open objQuery, objConnectionDB, adOpenStatic, adLockOptimistic
objRecordSet.MoveFirst
 
Do Until objRecordSet.EOF
objOutput = ""
For n = 0 To objRecordSet.Fields.Count - 1
  objOutput = objOutput & ";" & Trim(objRecordSet.Fields(n))
Next
 
sSplit = Split(objOutput, ";")
sPackageName = sSplit(2)
 
AdjustPrograms(sPackageName)
 
objRecordSet.MoveNext
Loop
 
End Function

VBScript: Auto Create SCCM Software Metering Rules

hicannet — Mon, 30 Jan 2012 12:12:42 +0000

During a previous project, we had a big bunch of Software Metering Rules defined in SMS and on paper. Since the import / migrate to SCCM not always seemed to work and we didn’t want to manually create all the rules, I decided to make a script for it.

The script uses an input.csv file as, you guessed it, input. The format of this file can be seen beneath the script and can of course be adjusted / extended.

create_software_metering_rules.vbs

'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' AUTHOR  : http://www.hican.net - @hicannet
' DATE    : 30-01-2012
' COMMENT : This script auto creates Software Metering 
'           Rules, based on an input file.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Option Explicit
 
Const ForWriting   = 2
Const ForReading   = 1
Const ForAppending = 8
 
Dim swbemLocator, swbemConnection, providerLoc, Location
Dim connectValue, returnValue, strInputFile
Dim objFso, objFile, strNextLine, strSplit
Dim checkExists, checkExist, strNameExists, newSWMRule
Dim newProductName, newFileName, newOriginalFileName, newFileVersion
Dim newLanguageID, newSiteCode, newApplyToChildSites
 
strInputFile  = ""
connectValue  = ""
 
WScript.Echo "Script Started..."
'***********************************'
'* This is where the magic happens *'
'***********************************'
On Error Resume Next
Err.Clear
returnValue = ConnectToSCCM
If Err.Number <> 0 Then
  Wscript.echo "Unable to connect."
Else
  CreateSWMRule()
End If
'***********************************'
'***********************************'
WScript.Echo "Script Finished.."
 
Function ConnectToSCCM
Set swbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set swbemConnection = swbemLocator.ConnectServer(connectValue, "root\sms")
Set providerLoc = swbemConnection.InstancesOf("SMS_ProviderLocation")
 
For Each Location In providerLoc
  If Location.ProviderForLocalSite = True Then
    Set swbemConnection = swbemLocator.ConnectServer(Location.Machine, "root\sms\site_" + Location.SiteCode)
    Exit For
  End If
Next
End Function
 
Function CreateSWMRule()
Set objFso = CreateObject("Scripting.FileSystemObject")
Set objFile = objFso.OpenTextFile(strInputFile, ForReading)
 
Do Until objFile.AtEndOfStream
  strNextLine = objFile.Readline
  strSplit = Split(strNextLine, ";")
 
  newProductName       = strSplit(0)
  newFileName          = strSplit(1)
  newOriginalFileName  = strSplit(2)
  newFileVersion       = strSplit(3)
  newLanguageID        = strSplit(4)
  newSiteCode          = strSplit(5)
  newApplyToChildSites = strSplit(6)
 
  If (Left(strNextLine, 1) = "*") Then
    WScript.Echo "DISABLED: " & newProductName 
  Else
    Set checkExists = swbemConnection.ExecQuery("Select * From SMS_MeteredProductRule Where OriginalFileName='" & newOriginalFileName & "'")
    For Each checkExist In checkExists
      strNameExists = checkExist.FileName
    Next
    If strNameExists <> newOriginalFileName Then
      ' Create the new MeteredProductRule object.
      Set newSWMRule = swbemConnection.Get("SMS_MeteredProductRule").SpawnInstance_
      ' Populate the SMS_MeteredProductRule properties.
      newSWMRule.ProductName= newProductName
      newSWMRule.FileName = newFileName
      newSWMRule.OriginalFileName =  newOriginalFileName
      newSWMRule.FileVersion = newFileVersion
      newSWMRule.LanguageID = newLanguageID
      newSWMRule.SiteCode = newSiteCode
      newSWMRule.ApplyToChildSites = newApplyToChildSites
      ' Save the new rule and properties.
      newSWMRule.Put_
 
      ' Output new rule name.
      WScript.Echo "CREATED: " & newProductName
    End If
  End If
Loop
objFile.Close
End Function

In the Input CSV the following (general) structure was used (the values are example values).

input.csv

1 2	All Adobe Reader;AcroRd32.exe;AcroRd32.exe;;;HIC1;True All Microsoft Project;WINPROJ.exe;WINPROJ.exe;;;HIC1;True

Miscellaneous: List Of Often Used Products And Their GUID’s

hicannet — Mon, 23 Jan 2012 07:03:00 +0000

In many projects I have been in, the migration of the Applications was one of the most important and complex tasks. We often encountered very old (legacy) applications, applications that had a hard time upgrading and old version, conflicting applications and more.

It was more than often required to write some uninstall scripts which killed specific running processes / programs and then uninstall the previous version(s) of the application(s). Sometimes we had a hard time finding the right program, because of bad written program code, corrupted installations, etc.

To ease up this process a bit, I made a short overview of often / common used applications and their respective ProductCode (GUID), Version and Language. This list can be used to create uninstall strings, scripts or just as an informative reference

Product / GUID Overview:

ADOBE READER
ProductName : Adobe Reader X
ProductCode : {AC76BA86-7AD7-1033-7B44-AA0000000001}
ProductVersion : 10.0.0
Language : ENGLISH

ProductName : Adobe Reader X – Français
ProductCode : {AC76BA86-7AD7-1036-7B44-AA0000000001}
ProductVersion : 10.0.0
Language : FRENCH

ProductName : Adobe Reader X – Deutsch
ProductCode : {AC76BA86-7AD7-1031-7B44-AA0000000001}
ProductVersion : 10.0.0
Language : GERMAN

ProductName : Adobe Reader X – Italiano
ProductCode : {AC76BA86-7AD7-1040-7B44-AA0000000001}
ProductVersion : 10.0.0
Language : ITALIAN

ProductName : Adobe Reader X – Japanese
ProductCode : {AC76BA86-7AD7-1041-7B44-AA0000000001}
ProductVersion : 10.0.0
Language : JAPANESE

ProductName : Adobe Reader X – Español
ProductCode : {AC76BA86-7AD7-1034-7B44-AA0000000001}
ProductVersion : 10.0.0
Language : SPANISH

ProductName : Adobe Reader X
ProductCode : {AC76BA86-7AD7-1033-7B44-AA1000000001}
ProductVersion : 10.1.0
Language : ENGLISH

ProductName : Adobe Reader X – Français
ProductCode : {AC76BA86-7AD7-1036-7B44-AA1000000001}
ProductVersion : 10.1.0
Language : FRENCH

ProductName : Adobe Reader X – Deutsch
ProductCode : {AC76BA86-7AD7-1031-7B44-AA1000000001}
ProductVersion : 10.1.0
Language : GERMAN

ProductName : Adobe Reader X – Italiano
ProductCode : {AC76BA86-7AD7-1040-7B44-AA1000000001}
ProductVersion : 10.1.0
Language : ITALIAN

ProductName : Adobe Reader X – Japanese
ProductCode : {AC76BA86-7AD7-1041-7B44-AA1000000001}
ProductVersion : 10.1.0
Language : JAPANESE

ProductName : Adobe Reader X – Español
ProductCode : {AC76BA86-7AD7-1034-7B44-AA1000000001}
ProductVersion : 10.1.0
Language : SPANISH

ADOBE ACROBAT
ProductName : Adobe Acrobat X Pro
ProductCode : {AC76BA86-1040-7D70-7760-000000000005}
ProductVersion : 10.0.0
Language : ITALIAN, SPANISH, DUTCH, PORTUGESE

ProductName : Adobe Acrobat X Pro
ProductCode : {AC76BA86-1033-F400-7760-000000000005}
ProductVersion : 10.0.0
Language : ENGLISH, FRENCH, GERMAN

ADOBE PHOTOSHOP ELEMENTS
ProductName : Adobe Photoshop Elements 1.0
ProductCode : {EDC10357-5A31-4142-8629-0EA84FF0623B}
ProductVersion : 1.0
Language : GERMAN

ProductName : Adobe Photoshop Elements 6.0
ProductCode : {F54AC413-D2C6-4A24-B324-370C223C6250}
ProductVersion : 6.0
Language : GERMAN

ProductName : Adobe Photoshop Elements 9
ProductCode : {007F778D-F15C-4EAB-AE92-071D21FAF632}
ProductVersion : 9.0
Language : ENGLISH

ADOBE PHOTOSHOP
ProductName : Adobe Photoshop CS2
ProductCame : {236BB7C4-4419-42FD-0407-1E257A25E34D}
ProductVersion : 9.0
Language : GERMAN

ProductName : Adobe Photoshop CS2
ProductCame : {236BB7C4-4419-42FD-040C-1E257A25E34D}
ProductVersion : 9.0
Language : FRENCH

ProductName : Adobe Photoshop CS2
ProductCame : {236BB7C4-4419-42FD-0409-1E257A25E34D}
ProductVersion : 9.0
Language : ENGLISH

ProductName : Adobe Photoshop CS5
ProductCame : {7AA40E69-5BD9-44B1-9B73-4FCD194D507C}
ProductVersion : 1.2.0000
Language : FRENCH

ProductName : Adobe Photoshop CS5
ProductCame : {9E5A78BE-4CD7-4C35-85F8-520B7DF6535B}
ProductVersion : 1.2.0000
Language : ENGLISH

MIRCOSOFT MAPPOINT
ProductName : Microsoft MapPoint Europe 2006
ProductCame : {83ED1E80-A1B7-4256-BCF1-AC4A88151A6B}
ProductVersion : 13.00.18.1200
Language : ENGLISH

ProductName : Microsoft MapPoint Europe 2010
ProductCame : {C82185E8-C27B-4EF4-2010-2222BC2C2B6D}
ProductVersion : 17.0.22.1400
Language : ENGLISH

MIRCOSOFT PROJECT
ProductName : Microsoft Office Project 2003 MUI
ProductCame : {90B40407-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.8173.0
Language : GERMAN

ProductName : Microsoft Office Project 2003 MUI
ProductCame : {90B40C0A-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.8173.0
Language : SPANISH

ProductName : Microsoft Office Project 2003 MUI
ProductCame : {90B4040C-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.8173.0
Language : FRENCH

ProductName : Microsoft Office Project Std 2003
ProductCame : {903A0409-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.8173.0
Language : ENGLISH

ProductName : Microsoft Office Project Pro 2003
ProductCame : {903B0407-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.8173.0
Language : GERMAN

ProductName : Microsoft Office Project Pro 2003
ProductCame : {903B0409-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.7969.0
Language : ENGLISH

MIRCOSOFT VISIO
ProductName : Microsoft Office Visio Std 2003
ProductCame : {90530409-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.7969.0
Language : ENGLISH

ProductName : Microsoft Office Visio Pro 2003
ProductCame : {90510407-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.8173.0
Language : GERMAN

ProductName : Microsoft Office Visio Pro 2003
ProductCame : {90510409-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.7969.0
Language : ENGLISH

ProductName : Microsoft Office Visio 2003 MUI
ProductCame : {905E0407-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.3216.5614
Language : GERMAN

ProductName : Microsoft Office Visio 2003 MUI
ProductCame : {905E0C0A-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.3216.5614
Language : SPANISH

ProductName : Microsoft Office Visio 2003 MUI
ProductCame : {905E040C-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.3216.5614
Language : FRENCH

ProductName : Microsoft Office Visio 2003 MUI
ProductCame : {905E0410-6000-11D3-8CFE-0150048383C9}
ProductVersion : 11.0.3216.5614
Language : ITALIAN

ProductName : Microsoft Visio Std 2010
ProductCame : {329B57A6-048C-43BB-93BE-7BBF8BA55C03}
ProductVersion : 3.0
Language : ENGLISH

ProductName : Microsoft Visio Std 2010
ProductCame : {41D5DCDB-FEB1-4AC4-8A02-816CC1D07975}
ProductVersion : 4.0
Language : FRENCH

ProductName : Microsoft Visio Std 2010
ProductCame : {D7BEC8BB-C5E9-426E-966F-94BD2A88C395}
ProductVersion : 2.0
Language : GERMAN

ProductName : Microsoft Visio Std 2010
ProductCame : {BA913A9D-8DEC-4C73-B8F5-6D1AE74D201B}
ProductVersion : 6.0
Language : SPANISH

VMWare
ProductName : VMware Player
ProductCame : {A53A11EA-0095-493F-86FA-A15E8A86A405}
ProductVersion : 3.0.0.9911
Language : ENGLISH

ProductName : VMware Workstation
ProductCame : {A3FF5CB2-FB35-4658-8751-9EDE1D65B3AA}
ProductVersion : 7.0.1.11056
Language : ENGLISH

ProductName : VMware Workstation
ProductCame : {0D94F75A-0EA6-4951-B3AF-B145FA9E05C6}
ProductVersion : 8.0.1.27038
Language : ENGLISH

VBScript: Install Oracle Webclient (Kill Predeploy.htm)

hicannet — Tue, 17 Jan 2012 11:13:11 +0000

Finally, after a long holiday, a new blog post and script again.
The script below is a very neat script which does a full silent (unattended) install of the Oracle Webclient / Siebel Mobile Client and kills the predeploy.htm! There aren’t much scripts on the internet which can do it like this script does.

Apart from some minor changes, the script is mainly written by a colleague of mine (who likes to stay low on the radar ). The script was written because a silent install was needed in the project we are working on. Oracle doesn’t support a silent install, therefore we had to write it ourselves (Oracle is lightyears behind with all kinds of stuff by the way).

Note #1: Change the value, on line 39, to the remote webserver in your environment!
Note #2: The script uses different kind of hta files, to give output / status information. These are just basic hta files. If you want an example, please contact me.

install_oracle_webclient.vbs (silent + kill predeploy.htm)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' AUTHOR  : http://www.hican.net - @hicannet
' DATE    : 17-01-2012
' COMMENT : This script installs the Oracle / Siebel
'           webclient and it kills the predeploy.htm
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Set objShell      = CreateObject("Wscript.Shell")
Set objFSO        = CreateObject("Scripting.FileSystemObject")
Set objLogFileFSO = CreateObject("Scripting.FileSystemObject")
Set wshSystemEnv  = objShell.Environment("SYSTEM")
Set objProcessEnv = objShell.Environment("PROCESS")
Set objReg        = GetObject("winmgmts:{impersonationLevel=" _ 
                    & "impersonate}!\\.\root\default:StdRegProv")
Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
 
CurrentDir        = Left(Wscript.ScriptFullname, InstrRev(Wscript.ScriptFullname, "\"))
strLogLocation    = objShell.ExpandEnvironmentStrings("%WinDir%") _ 
                    & "\system32\logfiles"
 
Const SilentParam        = " /qb!"
Const AllUsers           = " ALLUSERS=1"
Const HKEY_LOCAL_MACHINE = &H80000002
Const ForWriting         = 2
Const ForReading         = 1
Const ForAppending       = 8
Const OverWriteFiles     = True
 
CreateFolderStructure(strLogLocation)
strLogLocation           = strLogLocation & "\"
strSiebelInstallLogFile  = strLogLocation & "Siebel_Web_Client_" _ 
                           & Replace(FormatDateTime(Now(), 2),"/","-") & ".log"
 
If  objLogFileFSO.FileExists(strSiebelInstallLogFile) Then
  Set objLogFile = objLogFileFSO.OpenTextFile(strSiebelInstallLogFile, ForWriting)
Else
  Set objLogFile = objLogFileFSO.CreateTextFile(strSiebelInstallLogFile)
End If
 
strremoteServerMobileClient = ""
strORACLE_HOME              = "C:\Siebel\8.1\Client_1"
strORACLE_HOME_NAME         = "Siebel8_home1"
strINVENTORY_LOCATION       = strLogLocation & "Siebel_Web_Client_" _ 
                              & Replace(FormatDateTime(Now(), 2),"/","-")
strArchitecture             = ""
strOperatingSystemCaption   = ""
strOperatingSystemVersion   = ""
 
' ------------------------------------------------------------------------------
' Find the processor architecture
' ------------------------------------------------------------------------------
Set colItems = objWMIService.ExecQuery("Select Architecture from Win32_Processor")
For Each objItem In colItems
  If objItem.Architecture = 0 Then strArchitecture = "x86"
  If objItem.Architecture = 9 Then strArchitecture = "x64"
Next
 
' ------------------------------------------------------------------------------
' Step 1: Checks the prerequisites. Windows Vista (and above) is not supported 
' by Oracle.
' ------------------------------------------------------------------------------
PrerequisiteChecks
 
' Avoid the File Open dialog.
objProcessEnv("SEE_MASK_NOZONECHECKS") = 1
 
' ------------------------------------------------------------------------------
' Step 2: Install ActivePerl
' ------------------------------------------------------------------------------
InstallActivePerl
 
' ------------------------------------------------------------------------------
' Step 3: Force shutdown of internet explorer
' ------------------------------------------------------------------------------
WriteToLog "Action: -> Executing: Kill both IE and Java processes (if running)"
fnKillProcess("iexplore.exe")
fnKillProcess("java.exe")
fnKillProcess("javaw.exe")
fnKillProcess("mshta.exe")
 
' ------------------------------------------------------------------------------
' Step 4: Install the Oracle Web Client 8.1 Silent
' ------------------------------------------------------------------------------
InstallOracleWebClient81Silent
 
' ------------------------------------------------------------------------------
' Step 5: Install the Oracle Web Client 8.1.1.3 Silent
' ------------------------------------------------------------------------------
InstallOracleWebClient8113Silent
 
' ------------------------------------------------------------------------------
' Step 6: Set the ORACLE_HOME system environment variable
' Step 7: Modify the PATH system and process environment variable.
' ------------------------------------------------------------------------------
ModifyEnvironmentVariables
 
' ------------------------------------------------------------------------------
' Step 8: Copy the Oracle Patches to a folder under ORACLE_HOME
' Step 9: Run 'OPatch' to upgrade the installation
' ------------------------------------------------------------------------------
InstallOraclePatches
 
' ------------------------------------------------------------------------------
' Step 10: Modify the start menu
' ------------------------------------------------------------------------------
ModifyStartMenu
 
' ------------------------------------------------------------------------------
' Step 11: Predeploy all the ocx, dll files for Internet Explorer. Also process 
' the .inf files.
' ------------------------------------------------------------------------------
PredeployOracleCABFiles
PredeployOracleINFFiles
 
WriteToLog "-------------------------------------------------------------------"
WriteToLog "Installation has completed."
WriteToLog "-------------------------------------------------------------------"
 
objProcessEnv.Remove("SEE_MASK_NOZONECHECKS")
fnKillProcess("mshta.exe")
 
Sub PrerequisiteChecks
' ------------------------------------------------------------------------------
' Subroutine: PrerequisiteChecks
' Checks the OS version. If Windows 7 (or higher) then quit.
' ------------------------------------------------------------------------------
 
' ------------------------------------------------------------------------------
' Step 1: find the OS version
' ------------------------------------------------------------------------------
Set colItems = objWMIService.ExecQuery("Select Version from Win32_OperatingSystem")
 
For Each objItem In colItems
  strOperatingSystemVersion = objItem.Version
Next
 
' ------------------------------------------------------------------------------
' Step 2: find the OS Caption
' ------------------------------------------------------------------------------
Set colItems = objWMIService.ExecQuery("Select Caption from Win32_OperatingSystem")
 
For Each objItem In colItems
  strOperatingSystemCaption = objItem.caption
Next
 
strMessage = "Found OS '" & strOperatingSystemCaption & _ 
             "' (" & strOperatingSystemVersion & ") (" & strArchitecture & ")"
WriteToLog strMessage
 
If Left(strOperatingSystemVersion,1) > 5 Then
  strMessage = "The OS '" & strOperatingSystemCaption & _ 
               "' is not supported by Oracle. The installation will be aborted."
  WriteToLog strMessage
  MsgBox strMessage,16,"Oracle Web Client"
  WScript.Quit
End If
End Sub
 
Sub ShowHTA(strHTAFile)
' ------------------------------------------------------------------------------
' Subroutine: ShowHTA(strHTAFile)
' Shows a HTA file on the screen.
' trHTAFile = "c:\folder\folder1\folder2\filename.hta"
' ------------------------------------------------------------------------------
fnKillProcess("mshta.exe")
strCommand = Chr(34) & strHTAFile & Chr(34)
WriteToLog "Action: -> Executing: " & Chr(34) & strHTAFile & Chr(34)
objshell.run Chr(34) & strHTAFile & Chr(34),0,False
End Sub
 
Sub CreateFolderStructure(strFolderNameToBeCreated)
' ------------------------------------------------------------------------------
' Subroutine: CreateFolderStructure(strFolderNameToBeCreated)
' Creates the folderstructure as mentioned. Do not add a trailing '\'
' strFolderNameToBeCreated = "c:\folder\folder1\folder2"
' ------------------------------------------------------------------------------
Dim arrFolders : arrFolders = split (strFolderNameToBeCreated,"\")
Dim strFolder  : strFolder  = ""
Dim objFolder
 
For Each objFolder In arrFolders
  strFolder = strFolder & objFolder
  If NOT objFSO.FolderExists(strFolder) Then
    objFSO.CreateFolder(strFolder)
  End If
  strFolder = strFolder & "\"
Next
End Sub
 
Function fnKillProcess(strProcessName)
' ------------------------------------------------------------------------------
' Function: fnKillProcess(strProcessName)
' Terminates the given processname.
' ------------------------------------------------------------------------------
Set fn_objWMIService = GetObject("winmgmts:{impersonationLevel=" _
                       & "impersonate}!\\.\root\cimv2")
Set colProcess = fn_objWMIService.ExecQuery ("Select * From Win32_Process")
For Each objProcess In colProcess
  If LCase(objProcess.Name) = LCase(strProcessName) Then
     objProcess.Terminate()
  End If
Next
End Function
 
Function fn_WaitForProcessToStart(strProcessName)
' ------------------------------------------------------------------------------
' Function: fn_WaitForProcessToStart(strProcessName)
' This function waits for a process to start. If the given processname is 
' running, then the function is quit.
' strProcessName = the process to be checked.
' ------------------------------------------------------------------------------
blnProcessFound = False
Set fn_objSWbemServices = GetObject("winmgmts:\\.\root\cimv2")
Do 
  WScript.Sleep 2500
  Set colSWbemObjectSet = fn_objSWbemServices.InstancesOf("Win32_Process")
  For Each objSWbemObject In colSWbemObjectSet
    If (LCase(objSWbemObject.Name) = LCase(strProcessName)) Then
      blnProcessFound = True
    End If
  Next
Loop Until blnProcessFound
End Function
 
Function fn_WaitForARunningProcess(strProcessName)
' ------------------------------------------------------------------------------
' Function: fn_WaitForARunningProcess(strProcessName)
' This function waits for a process to stop. When the processname is not 
' running anymore, this function will quit.
' strProcessName = the process to be checked.
' ------------------------------------------------------------------------------
Set fn_objSWbemServices = GetObject("winmgmts:\\.\root\cimv2")
Set colSWbemObjectSet = fn_objSWbemServices.InstancesOf("Win32_Process")
For Each objSWbemObject In colSWbemObjectSet
  If (LCase(objSWbemObject.Name) = LCase(strProcessName)) Then
    Wscript.Sleep(2500)
    fn_WaitForARunningProcess(strProcessName)
  End If
Next
End Function
 
Function WriteToLog(sLogMessage)
' ------------------------------------------------------------------------------
' Function: WriteToLog(sLogMessage)
' This function writes an entry in a log file.
' sLogMessage = The message to be written in the log file.
' ------------------------------------------------------------------------------
  objLogFile.WriteLine("Time: " & now & "  " & sLogMessage)
End Function
 
Function fnWriterunningProcessesToLogFile()
' ------------------------------------------------------------------------------
' Function: fnWriterunningProcessesToLogFile
' Writes all the running processes to a log file.
' ------------------------------------------------------------------------------
Set fn_objWMIService = GetObject("winmgmts:{impersonationLevel=" _
                       & "impersonate}!\\.\root\cimv2")
 
Set colProcess = fn_objWMIService.ExecQuery ("Select * From Win32_Process")
For Each objProcess In colProcess
  WriteToLog(" --> Running process: " & objProcess.Name)
Next
End Function
 
' ------------------------------------------------------------------------------
' The following subroutines are used to install the components.
' ------------------------------------------------------------------------------
Sub InstallActivePerl
' ------------------------------------------------------------------------------
' Sub InstallActivePerl
' Only installs ActivePerl if not already installed.
' Use WMI to find the processor architecture.
' The variable %PROCESSOR_ARCHITECTURE% always returns x86 (under sytem 
' context). That is why WMI is used.
' ------------------------------------------------------------------------------
If strArchitecture = "x86" Then
  strMSIFileName = CurrentDir & "1-ActivePerl" & Chr(92) _ 
                   & "ActivePerl-5.14.2.1402-MSWin32-x86-295342.msi"
  strLogfile = "ActivePerl-5.14.2.1402-MSWin32-x86-295342.log"
  strExecuteCommand = "msiexec.exe /i " & Chr(34) & strMSIFileName _ 
                      & Chr(34) & SilentParam & Allusers & " /l*v " _ 
                      & Chr(34) & strLogLocation & strLogfile & Chr(34)
  WriteToLog "Action: -> Executing: " & strExecuteCommand
  objShell.Run strExecuteCommand,0,True
End If
 
If strArchitecture = "x64" Then
  strMSIFileName = CurrentDir & "1-ActivePerl" & Chr(92) _ 
                   & "ActivePerl-5.14.2.1402-MSWin32-x64-295342.msi"
  strLogfile = "ActivePerl-5.14.2.1402-MSWin32-x64-295342.log"
  strExecuteCommand = "msiexec.exe /i " & Chr(34) & strMSIFileName & Chr(34) _ 
                      & SilentParam & Allusers & " /l*v " & Chr(34) _ 
                      & strLogLocation & strLogfile & Chr(34)
  WriteToLog "Action: -> Executing: " & strExecuteCommand
  objShell.Run strExecuteCommand,0,True
End If
End Sub
 
Sub InstallOracleWebClient81Silent
' ------------------------------------------------------------------------------
' Sub InstallOracleWebClient81Silent
' Installs the Oracle Web Client 8.1
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_1_Installing_8.1.hta")
 
strFROM_LOCATION  = CurrentDir & "2-8.1\Siebel_Web_Client\Disk1\stage\products.xml"
strExecuteCommand = Chr(34) & CurrentDir _
                    & "2-8.1\Siebel_Web_Client\Disk1\install\oui.exe" & Chr(34) _ 
                    & " -ignoreSysPrereqs -noconsole -silent -nowait -force" _ 
                    & " -responseFile " & Chr(34) & CurrentDir _ 
                    & "6-RSPFiles\Siebel81.rsp" & Chr(34) _ 
                    & " FROM_LOCATION=" & Chr(34) & strFROM_LOCATION & Chr(34) _ 
                    & " remoteServerMobileClient=" & Chr(34) _ 
                    & strremoteServerMobileClient & Chr(34) & " ORACLE_HOME=" _ 
                    & Chr(34) & strORACLE_HOME & Chr(34) & " ORACLE_HOME_NAME=" _ 
                    & Chr(34) & strORACLE_HOME_NAME & Chr(34) _ 
                    & " INVENTORY_LOCATION=" & Chr(34) & strINVENTORY_LOCATION _ 
                    & Chr(34)
WriteToLog "Action: -> Executing: " & strExecuteCommand
blnResult = objShell.Run (strExecuteCommand)
 
WriteToLog "Action: -> Now wait for Internet Explorer screen to come up"
fn_WaitForProcessToStart("iexplore.exe")
WriteToLog "Action: -> Executing: Kill Internet Explorer process"
fnKillProcess ("iexplore.exe")
 
WriteToLog "Action: -> Now wait for Java to finish."
' If run without the -noconsole parameter, then wait for java.exe
fn_WaitForARunningProcess("javaw.exe")
End Sub
 
Sub InstallOracleWebClient8113Silent
' ------------------------------------------------------------------------------
' Sub InstallOracleWebClient8113Silent
' Installs the Oracle Web Client 8.1.1.3
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_2_Installing_8.1.1.3.hta")
 
strFROM_LOCATION  = CurrentDir _
                    & "3-8.1.1.3\Client\Siebel_Web_Client\Disk1\stage\products.xml"
strExecuteCommand = Chr(34) & CurrentDir _ 
                    & "3-8.1.1.3\Client\Siebel_Web_Client\Disk1\install\oui.exe" _ 
                    & Chr(34) & " -ignoreSysPrereqs -noconsole -silent -nowait" _ 
                    & " -force -responseFile " & Chr(34) & CurrentDir _ 
                    & "6-RSPFiles\Siebel8113.rsp" & Chr(34) _ 
                    & " FROM_LOCATION=" & Chr(34) & strFROM_LOCATION & Chr(34) _ 
                    & " ORACLE_HOME=" & Chr(34) & strORACLE_HOME & Chr(34) _ 
                    & " ORACLE_HOME_NAME=" & Chr(34) & strORACLE_HOME_NAME _ 
                    & Chr(34) & " INVENTORY_LOCATION=" & Chr(34) _ 
                    & strINVENTORY_LOCATION & Chr(34)
WriteToLog "Action: -> Executing: " & strExecuteCommand
blnResult = objShell.Run (strExecuteCommand)
 
WriteToLog "Action: -> Wait for Oracle Universal Installer and Java to finish."
fn_WaitForARunningProcess("oui.exe")
WScript.Sleep 10000
'If run without the -noconsole parameter, then wait for java.exe
fn_WaitForARunningProcess("javaw.exe")
End Sub
 
Sub ModifyEnvironmentVariables
' ------------------------------------------------------------------------------
' Sub ModifyEnvironmentVariables
' Modifies the System Environment variables. 
' ------------------------------------------------------------------------------
wshSystemEnv("ORACLE_HOME") = strORACLE_HOME
WriteToLog "The system environment value 'ORACLE_HOME' has been set to " _ 
           & strORACLE_HOME
 
strPATH = wshSystemEnv("PATH")
WriteToLog "The system environment variable PATH has as value: " & strPATH
If InStr(strPATH,"perl") = 0 Then
  wshSystemEnv("PATH")="C:\Perl\bin;" & strPATH
  WriteToLog "The system environment variable PATH has been modified. The " _ 
	           & "new value is " & wshSystemEnv("PATH")
Else
  WriteToLog "The system environment variable PATH has not been modified."
End If
End Sub
 
Sub InstallOraclePatches
' ------------------------------------------------------------------------------
' Sub InstallOraclePatches
' Copies the files to ORACLE_HOME. Then installs 2 oracle Patches. 
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_3_Copy_files.hta")
objFSO.CopyFolder CurrentDir & "4-QF0312" , strORACLE_HOME & "\",OverWriteFiles
objFSO.CopyFolder CurrentDir & "5-QF1302" , strORACLE_HOME & "\",OverWriteFiles
objFSO.CopyFile CurrentDir & "6-RSPFiles\ocm.rsp" , strORACLE_HOME _ 
                           & "\",OverWriteFiles
ShowHTA(CurrentDir & "step_4_Installing_Patch_QF0312.hta")
 
strCommand = "c:\Perl\bin\perl.exe " & strORACLE_HOME _
             & "\4-QF0312\Siebel_Web_Client\OPatch\opatch.pl apply " _
             & strORACLE_HOME & "\4-QF0312\Siebel_Web_Client -silent -force " _
             & "-ocmrf " & strORACLE_HOME & "\ocm.rsp -oh " & strORACLE_HOME
WriteToLog "Action: -> Executing: 'objShell.Run " & strCommand & ",0,True'"
objShell.Run strCommand,0,True
 
ShowHTA(CurrentDir & "step_5_Installing_Patch_QF1302.hta")
 
strCommand = "c:\Perl\bin\perl.exe " & strORACLE_HOME _
             & "\5-QF1302\Siebel_Web_Client\OPatch\opatch.pl apply " _
             & strORACLE_HOME & "\5-QF1302\Siebel_Web_Client -silent -force " _
             & "-ocmrf " & strORACLE_HOME & "\ocm.rsp -oh " & strORACLE_HOME
WriteToLog "Action: -> Executing: 'objShell.Run " & strCommand & ",0,True'"
objShell.Run strCommand,0,True
End Sub
 
Sub ModifyStartMenu
' ------------------------------------------------------------------------------
' Sub ModifyStartMenu
' Removes all unneeded entries from the Start menu and add one shortcut.  
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_6_Modifying_start_menu.hta")
 
strKeyPath   = "SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
strValueName = "Common Programs"
objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strCommonPrograms
 
If objFSO.FolderExists (strCommonPrograms & "\ActivePerl 5.14.2 Build 1402") Then
  WriteToLog "Action: -> Deleting: " & strCommonPrograms _
	           & "\ActivePerl 5.14.2 Build 1402"
  objFSO.DeleteFolder (strCommonPrograms & "\ActivePerl 5.14.2 Build 1402")
End If
 
If objFSO.FolderExists (strCommonPrograms & "\Oracle - " & strORACLE_HOME_NAME) Then
  WriteToLog "Action: -> Deleting: " & strCommonPrograms & "\Oracle - " _ 
	           & strORACLE_HOME_NAME
  objFSO.DeleteFolder (strCommonPrograms & "\Oracle - " & strORACLE_HOME_NAME)
End If
 
If objFSO.FolderExists (strCommonPrograms & Chr(92) & strORACLE_HOME_NAME) Then 
  WriteToLog "Action: -> Deleting: " & strCommonPrograms & "\" & strORACLE_HOME_NAME
  objFSO.DeleteFolder (strCommonPrograms & "\" & strORACLE_HOME_NAME)
End If 
 
Set objLink              = objShell.CreateShortcut(strCommonPrograms _ 
                           & "\Siebel Field Service - ENU.lnk")
objLink.Description      = "Siebel Field Service - ENU"
objLink.IconLocation     = strORACLE_HOME & "\bin\siebel.exe,0"
objLink.TargetPath       = strORACLE_HOME & "\bin\siebel.exe" 
objLink.Arguments        = "/c " & strORACLE_HOME & "\bin\enu\sfs.cfg"
objLink.WindowStyle      = 1
objLink.WorkingDirectory = strORACLE_HOME & "\bin"
objLink.Save
 
WriteToLog "Action: -> Created: icon 'Siebel Field Service - ENU' in " _ 
           & strCommonPrograms
End Sub
 
Sub PredeployOracleCABFiles
' ------------------------------------------------------------------------------
' Sub PredeployOracleCABFiles
' Extracts all the cab files to C:\Windows\Downloaded Program Files.  
' Then the files are registered. 
' ------------------------------------------------------------------------------
ShowHTA(CurrentDir & "step_7_predeploy.hta")
 
Set strFolderwithCABFiles = objFSO.GetFolder(strORACLE_HOME _ 
                            & "\PUBLIC\enu\21219\APPLETS")
Set arrCABFiles           = strFolderwithCABFiles.Files
strKeyPathDPF             = "SOFTWARE\Microsoft\Windows\CurrentVersion" _ 
                            & "\Internet Settings\ActiveX Cache"
strValueNameDPF           = "0"
objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPathDPF,strValueNameDPF,strValueDPF
WriteToLog "Folder for Downloaded Program Files is: " & strValueDPF
 
For Each objCABFile In arrCABFiles
  If LCase(Right(objCABFile.Name,4)) = ".cab" Then
    strCommand = "expand -f:*.* " & strORACLE_HOME & "\PUBLIC\enu\21219\APPLETS\" _ 
		             & objCABFile.Name & " " & Chr(34) & strValueDPF & Chr(34)
    WriteToLog "Action: - Executing: objShell.Run " & strCommand & ",0,True"
    objShell.Run StrCommand,0,True
  End If
Next
 
Set strFolderwithDPFiles = objFSO.GetFolder(strValueDPF)
Set arrDPFiles           = strFolderwithDPFiles.Files
WriteToLog "Action: -> Registering or deleting the files in " & strValueDPF
 
For Each objDPFile In arrDPFiles
  strDPFile = lcase(objDPFile.Name)
  If (Left(strDPFile,1)="s" AND Right(strDPFile,4)=".dll") OR _ 
     (Left(strDPFile,1)="s" AND Right(strDPFile,4)=".ocx") OR _ 
     (Left(strDPFile,4)="ieop" AND Right(strDPFile,4)=".dll") Then
    strCommand = "regsvr32 /s " & Chr(34) & strValueDPF & "\" & strDPFile & Chr(34)
    valResult  = objShell.Run(strCommand,6,True)
    If valResult = 0 Then
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' succeeded."
    Else
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' failed."
    End If
  End If
  If (Left(strDPFile,1)="s" AND Right(strDPFile,4)=".exe") Then
    strCommand = Chr(34) & strValueDPF & "\" & strDPFile & Chr(34) & " /regserver"
    valResult  = objShell.Run(strCommand,1,True)
    If valResult = 0 Then
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' succeeded."
    Else
      WriteToLog "Action: 'objShell.Run(" & strCommand & ",6,True)' failed."
    End If
  End If
  If Right(strDPFile,6)=".class" Then
    objFSO.DeleteFile strValueDPF & "\" & strDPFile
    WriteToLog "Action: The file '" & strValueDPF & Chr(92) & strDPFile _ 
               & "' has been deleted."
  End If
Next
End Sub
 
Sub PredeployOracleINFFiles
' ------------------------------------------------------------------------------
' Sub PredeployOracleINFFiles
' Reads all the .inf files in C:\Windows\Downloaded Program Files. Finds the 
' dll file in the inf file
' and then adds the registration in the registry.
' ------------------------------------------------------------------------------
strKeyPathDPF             = "SOFTWARE\Microsoft\Windows\CurrentVersion" _ 
                            & "\Internet Settings\ActiveX Cache"
strKeyPathModuleUsage     = "SOFTWARE\Microsoft\Windows\CurrentVersion\ModuleUsage\"
strValueNameDPF           = "0"
objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPathDPF,strValueNameDPF,strValueDPF
WriteToLog "Folder for Downloaded Program Files is: " & strValueDPF
 
Set strFolderwithINFFiles = objFSO.GetFolder(strValueDPF)
Set arrINFFiles           = strFolderwithINFFiles.Files
WriteToLog "Action: -> Processing the INF files in " & strValueDPF
 
For Each objINFFile In arrINFFiles
  strINFFile = LCase(objINFFile.Name)
  If Right(strINFFile,4) = ".inf" Then
    strINFFile = strValueDPF & "\" & strINFFile
    WriteToLog "Action: -> Processing INF File: " & strINFFile
    Set objINFFileToRead = objFSO.OpenTextFile(strINFFile, ForReading, False)
    Do While NOT objINFFileToRead.AtEndOfStream
      strLine = Trim(objINFFileToRead.ReadLine)
      strLine = lcase(strLine)
      If Left(strLine,1) = "[" AND Right(strLine,5)=".dll]" Then
        strDLLFileName      = strLine
        ' Remove first '['
        strDLLFileName      = Right(strDLLFileName,Len(strDLLFileName)-1)
        ' Remove last ']'
        strDLLFileName      = Left (strDLLFileName,Len(strDLLFileName)-1)
        WriteToLog "Action: -> Found dll file " & strDLLFileName & " in " _ 
                   & strINFFile & "."
        strDLLFileName = strValueDPF & Chr(92) & strDLLFileName
      End If
      If Left(strLine,5) = "clsid" Then
        arrCLSID = Split(strLine,"=")
        strCLSID = arrCLSID(1)
        WriteToLog "Action: -> Found CLSID " & strCLSID  & " in " & strINFFile & "."
      End If
      strDLLFileName = replace(strDLLFileName, "\","/")
      objReg.CreateKey HKEY_LOCAL_MACHINE,strKeyPathModuleUsage & strDLLFileName
      WriteToLog "Action: -> Created registry key: HKEY_LOCAL_MACHINE\" _ 
                 & strKeyPathModuleUsage & strDLLFileName
      objReg.SetStringValue HKEY_LOCAL_MACHINE,strKeyPathModuleUsage _ 
      & strDLLFileName , ".Owner" , strCLSID
      WriteToLog "Action: -> Created hive '.Owner' with value " & strCLSID _ 
                 & " in HKEY_LOCAL_MACHINE\" & strKeyPathModuleUsage & strDLLFileName
      objReg.SetStringValue HKEY_LOCAL_MACHINE,strKeyPathModuleUsage _ 
      & strDLLFileName , strCLSID , ""
      WriteToLog "Action: -> Created hive '" & strCLSID _ 
                 & "' with an empty value in HKEY_LOCAL_MACHINE\" _ 
                 & strKeyPathModuleUsage & strDLLFileName
    Loop
  End If
Next
End Sub

PowerShell: Create Active Directory Users Based On Excel Input

hicannet — Fri, 23 Dec 2011 09:42:40 +0000

The last script / message just before I leave on a 2 week skiing holiday! Sooo, make good use of this, because you won’t hear from me earlier than the 8th or 9th of January

About the script now. This script will create users in Active Directory based on the settings in the input file (see the Excel / CSV file below this script for an example of the input file used). These settings can, of course, be changed or extended (check this Microsoft Technet Link to get an overview of all the settings that can be set with the PowerShell New-ADUser Cmdlet).

Not only can the file be extended (or decreased) it can also be altered. The column names can be changed (note that you also need to change it in the PowerShell script), the columns can be re-ordered, etc. The script will keep working, because it uses the column names!

Note #1: This script makes use of the Active Directory Module for PowerShell.
Note #2: Feel free to contact me if anything isn’t clear, doesn’t work or to see something changed.

create_ad_users.ps1

#######################################################
# AUTHOR  : http://www.hican.net - @hicannet
# DATE    : 28-11-2011
# COMMENT : This script creates new Active Directory users
#           including different kind of properties based
#           on an input_create_ad_users.csv.
Import-Module ActiveDirectory
# Get current directory and set import file in variable
$path     = Split-Path -parent $MyInvocation.MyCommand.Definition
$newpath  = $path + "\import_create_ad_users.csv"
# Define variables
$log      = $path + "\create_ad_users.log"
$date     = Get-Date
$i        = 0
# Change this to the location you want the users to be created in your AD
$location = "OU=Test,OU=Users,DC=hican,DC=net"
# FUNCTIONS
Function createUsers
{
  "Created following users (on " + $date + "): " | Out-File $log -append
  "--------------------------------------------" | Out-File $log -append
  Import-CSV $newpath | ForEach-Object { 
    # A check for the country, because those were full names and need 
    # to be landcodes in order for AD to accept them. I used Netherlands 
    # as example
    If($_.CO -eq "Netherlands")
    {
      $_.CO = "NL"
    }
    # Replace dots / points (.) in names, because AD will error when a 
    # name ends with a dot (and it looks cleaner as well)
    $replace = $_.CN.Replace(".","")
    If($replace.length -lt 4)
    {
      $lastname = $replace
    }
    Else
    {
      $lastname = $replace.substring(0,4)
    }
    # Create sAMAccountName according to this 'naming convention':
    #  for example
    # hhica
    $sam = $_.Initials.substring(0,1).ToLower() + $lastname.ToLower()
    Try   { $exists = Get-ADUser -LDAPFilter "(sAMAccountName=$sam)" }
    Catch { }
    If(!$exists)
    {
      $i++
      # Set all variables according to the table names in the Excel 
      # sheet / import CSV. The names can differ in every project, but 
      # if the names change, make sure to change it below as well.
      $setpass = ConvertTo-SecureString -AsPlainText $_.Password -force
      New-ADUser $sam -GivenName $_.GivenName -Initials $_.Initials ` 
      -Surname $_.SN -DisplayName $_.DisplayName -Office $_.OfficeName `
      -Description $_.Description -EmailAddress $_.Mail ` 
      -StreetAddress $_.StreetAddress -City $_.L `
      -PostalCode $_.PostalCode -Country $_.CO -UserPrincipalName $_.UPN ` 
      -Company $_.Company -Department $_.Department -EmployeeID $_.ID ` 
      -Title $_.Title -OfficePhone $_.Phone -AccountPassword $setpass
 
      # Set an ExtensionAttribute
      $dn  = (Get-ADUser $sam).DistinguishedName
      $ext = [ADSI]"LDAP://$dn"
      $ext.Put("extensionAttribute1", $_.ExtensionAttribute1)
      $ext.SetInfo()
 
      # Move the user to the OU you set above. If you don't want to
      # move the user(s) and just create them in the global Users
      # OU, comment the string below
      Move-ADObject -Identity $dn -TargetPath $location
 
      # Rename the object to a good looking name (otherwise you see
      # the 'ugly' shortened sAMAccountNames as a name in AD. This 
      # can't be set right away (as sAMAccountName) due to the 20
      # character restriction
      $newdn = (Get-ADUser $sam).DistinguishedName
      Rename-ADObject -Identity $newdn -NewName $_.CN
 
      $output  = $i.ToString() + ") Name: " + $_.CN + "  sAMAccountName: " 
      $output += $sam + "  Pass: " + $_.Password
      $output | Out-File $log -append
    }
    Else
    {
      "SKIPPED - ALREADY EXISTS OR ERROR: " + $_.CN | Out-File $log -append
    }
  }
  "----------------------------------------" + "`n" | Out-File $log -append
}
# RUN SCRIPT
createUsers
#Finished

In the Excel file / Input CSV the following (general) structure was used (the values are example values).

import_create_ad_users.csv

# LINE1 (the table headings in the Excel)
 
# Already_In_AD,CN,GivenName,Initials,SN,DisplayName,OfficeName,
# Description,Mail,StreetAddress,L,PostalCode,
# CO,UPN,Title-i,Company,Department,ID,ExtensionAttribute1,Title,
# Phone,Manager,Password
 
# LINE2 (first entry, all other entries look the same. As you can see
# there are also tables which aren't used, but are no problem for
# the script to work!
 
# NO,Net.Hican,Hican,H.,Net,"Net, H. - Hican -",Hican Building,
# Hican Net,info@hican.net,Hicanstreet 1,Hicancity,1337,
# Netherlands,info@hican,i-CEO,Hican.net,*,HIC1337,Staff,CEO,
# +0000000000,,IDDQD

PowerShell: Migrate Active Directory Group Memberships Between Global Groups

hicannet — Mon, 19 Dec 2011 12:21:33 +0000

During one of my projects at a customer the Active Directory setup needed to change. In this particular AD, they had defined Job Titles (Global Groups) in a Job Title OU. Specific Application Groups were members of these Job Titles to make sure that people who were in any of those Job Titles got the applications they needed to do their jobs.

Along the way it was decided that these Job Titles didn’t fit the purpose anymore and a decision was made to use Job Profiles instead. This caused quite an extreme reduction of (Global) Groups in AD (approximately from 350+ per country OU to 12+).

In order to make the Job Title applications available to the matching profiles, a AD Group Migration had to be done. I decided to do that in Powershell (without any knowledge ) instead of VBScript this time. Below is the result which, I am sure, can be written shorter and more logical, but it’s a start.

The script makes use of an input.csv which contained a ‘translation table’ to match the new Profile Groups with the old Job Title Groups.

Note #1: This is part one of a batch of 6 scripts. The other scripts will be posted later on, since some are still under development and all scripts can be run separately.
Note #2: This script makes use of the Active Directory Module for PowerShell.

migrate_ad_group_membership.ps1

#######################################################
# AUTHOR  : http://www.hican.net - @hicannet
# DATE    : 24-11-2011
# COMMENT : This script populates the new RBAC Profile 
#           groups with all the applications that can /
#           need to be linked to these groups (based 
#           upon the RBAC JobTitle groups).
#######################################################
Import-Module ActiveDirectory
# Dynamic fill of the input Array
# The input.csv looks like this (groups names without country code):
# ,
# ,
$path     = Split-Path -parent $MyInvocation.MyCommand.Definition
$path     = $path + "\input.csv"
$groups   = Get-Content $path
# Country code array (due to the complexity of the AD OU structure)
$country  = "","",""
# FUNCTIONS
Function populateRBACProfiles
{
  # Loop through all countries in the $country array
  Foreach ($cntry In $country)
  {
    $rbacs = Get-ADGroup -Filter * -SearchBase ("OU=RBAC Title Groups,OU="+$cntry+",OU=Groups,DC=hican,DC=net")
    Foreach ($group In $groups)
    {
      # Split the values of the input.csv and rename to match the projects AD.
      $split   = $group.split(",")
      $string  = $cntry+"-GG.RBAC."+$split[0]
      $stringN = $cntry+"-GG."+$split[1]
      Foreach ($rbac In $rbacs)
      {
        If ($string -eq ($rbac | %{$_.Name}))
        {
          $apps = Get-ADGroup -Identity $string -Properties memberof | Select -expandproperty memberof
          Foreach ($app In $apps)
          {
            If($app)
            {
              # Trap any errors
              Try   { $exists = Get-ADGroupMember $app | %{$_.Name} }
              Catch { }
              # If they match and are existant, add them to the appropriate RBAC Profile Group (mentioned in the input.csv)
              If ($exists -notcontains $stringN)
              {
                Add-ADGroupMember $app $stringN -Confirm:$false
              }
            }
          }
        }
      }
    }
  }
}
# RUN SCRIPT
populateRBACProfiles
"SCRIPT FINISHED"

VBScript: Output Active Directory User Information To Excel

hicannet — Wed, 14 Dec 2011 13:07:56 +0000

During a project I was asked to create reports about specific Active Directory values of all the users / members in a specific (application) group. I am quite sure that this script can be written in less code (especially in Powershell), but it does the trick.

It first checks the ‘base’ of the group you are targeting and reads all the members of that group. It then recursively retrieves all the members of any sub / linked groups. All these results are written to a nice defined Excel sheet to handout to your Projectleader, Manager or whatever

If you want to add more (default) LDAP properties to the report, you can use the following link to look them up:

- LDAP Properties

create_group_report.vbs

'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' AUTHOR  : http://www.hican.net - @hicannet
' DATE    : 23-03-2011
' COMMENT : This script creates an Excel with 
'           different kind of information about all
'           the users / members of a specific AD Group.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Option Explicit
 
Const xlContinuous = 1
Const xlThin       = 2
 
Dim objExcel, objWorkbook, objWorksheet
Dim objCommand, objRecordSet, objConnection
Dim objMember, sGroupDN, sTargetGroupDN, objGroup
Dim intRow, sCount, sOutputFile, objUAC
 
Set objConnection      = CreateObject("ADODB.Connection")
Set objCommand         = CreateObject("ADODB.Command")
Set objRecordSet       = CreateObject("ADODB.Recordset")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection
 
'Give the LDAP DN / CN for a group here, for example:
'LDAP://CN=TestGroup,OU=Groups,DC=hican,DC=net
sTargetGroupDN   = ""
sOutputFile      = ""
 
Set objExcel     = CreateObject("Excel.Application")
objExcel.Visible = True
Set objWorkbook  = objExcel.Workbooks.Add()
Set objWorksheet = objWorkbook.Worksheets(1)
intRow           = 2
sCount           = 1
 
createUserList(sTargetGroupDN)
 
objExcel.Range("A1:H1").autofilter
objExcel.Range("A1").Select
objExcel.ActiveWorkbook.SaveAs sOutputFile
objExcel.ActiveWorkbook.Close
objExcel.Application.Quit
 
Wscript.Quit
 
Function createUserList(sGroupDN)
Set objGroup = GetObject(sGroupDN)
 
objWorksheet.Cells(sCount,1) = "sAMAccountName"
objWorksheet.Cells(sCount,1).BorderAround xlContinuous, xlThin
objWorksheet.Cells(sCount,2) = "First Name"
objWorksheet.Cells(sCount,2).BorderAround xlContinuous, xlThin
objWorksheet.Cells(sCount,3) = "Last Name"
objWorksheet.Cells(sCount,3).BorderAround xlContinuous, xlThin
objWorksheet.Cells(sCount,4) = "Employee Number"
objWorksheet.Cells(sCount,4).BorderAround xlContinuous, xlThin
objWorksheet.Cells(sCount,5) = "Email Address"
objWorksheet.Cells(sCount,5).BorderAround xlContinuous, xlThin
objWorksheet.Cells(sCount,6) = "IP Telephone Number"
objWorksheet.Cells(sCount,6).BorderAround xlContinuous, xlThin
objWorksheet.Cells(sCount,7) = "Country"
objWorksheet.Cells(sCount,7).BorderAround xlContinuous, xlThin
objWorksheet.Cells(sCount,8) = "Disabled"
objWorksheet.Cells(sCount,8).BorderAround xlContinuous, xlThin
 
objWorksheet.Range("A1:H1").Font.Bold = True
objWorksheet.Range("A1:H1").Interior.ColorIndex = 15
 
For Each objMember in objGroup.Members
  If (LCase(objMember.Class) = "user") Then  
    objWorksheet.Cells(intRow, 1).Value = objMember.sAMAccountName
    objWorksheet.Cells(intRow, 2).Value = objMember.GivenName
    objWorksheet.Cells(intRow, 3).Value = objMember.SN
    objWorksheet.Cells(intRow, 4).Value = ""
    objWorksheet.Cells(intRow, 5).Value = objMember.Mail
    objWorksheet.Cells(intRow, 6).Value = objMember.ipPhone
    objWorksheet.Cells(intRow, 7).Value = objMember.c & " - " & objMember.l
    If objMember.userAccountControl = 514 Then
      objUAC = "Yes"
    Else
      objUAC = ""
    End If
    objWorksheet.Cells(intRow, 8).Value = objUAC
    objWorksheet.Range("A1:H1").Select
    objWorksheet.Cells.EntireColumn.AutoFit
  Else
    ' This is to retrieve members recursively
    ' Comment the Function to only get the 'base'
    createUserList(objMember.AdsPath)
    intRow = intRow - 1
  End If
 
  intRow = intRow + 1
Next
 
Set objGroup = Nothing
End Function